[nazarenko]

Подскажите, пожайлуста,
как вывести Розничную цену в справочнике номенклатура
через событие ПриПолученииДанных
в списке справочника номенклатура (рядом с каждым наименованием).

Для 1С: 8.2 УТП для Украины 1.2.9.1 от 23.08.2012.
В типовой конфигурации цены выводятся внизу только
для одной текущей позиции.

Спасибо.

[logist]

Добавляете в список колонку и используя событие ПриВыводеСтроки получаете цену для строки и заполняете в соотв. колонку.
ПриПолученииДанных тут как то не подходит.

[Ardi]

ПриПолученииДанных тут как то не подходит.

Подходит.

[sava1]

Подходит.

+ 100 - Не просто подходит, а необходимо.

Топикстартеру -
в запрос по остаткам добавляем выборку по ценам - подставляем аналогично

[Vofka]

Как раз ПриВыводеСтроки не подходит. Сделать тудой можно, но правильнее ПриПолученииДанных.

nazarenko, сделайте по аналогии с номенклатурой, другой регистр прицепите.

Сообщение отредактировал Vofka - 09.10.12, 12:30

[ignsv]

Процедура СписокПриПолученииДанных(Элемент, ОформленияСтрок)
    Запрос = Новый Запрос("ВЫБРАТЬ
                          |    ЦеныНоменклатурыСрезПоследних.Номенклатура,
                          |    ЦеныНоменклатурыСрезПоследних.Цена,
                          |    ПРЕДСТАВЛЕНИЕ(ЦеныНоменклатурыСрезПоследних.Валюта) КАК валюта
                          |ИЗ
                          |    РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
                          |            ,
                          |            Номенклатура В (&сНом)
                          |                И ТипЦен = &ТекущийТип) КАК ЦеныНоменклатурыСрезПоследних"); 

    МассивНоменклатуры = Новый Массив; 
    Соответствие = Новый Соответствие; 

    Для Каждого Строка из ОформленияСтрок Цикл 
        Если НЕ Строка.ДанныеСтроки.Ссылка.ЭтоГруппа Тогда
        МассивНоменклатуры.Добавить(Строка.ДанныеСтроки.Ссылка); 
        Соответствие.Вставить(Строка.ДанныеСтроки.Ссылка, Строка);
        КонецЕсли;
    КонецЦикла; 

    Запрос.УстановитьПараметр("сНом", МассивНоменклатуры); 
    Запрос.УстановитьПараметр("ТекущийТип", Справочники.ТипыЦенНоменклатуры.НайтиПоНаименованию("VIP")); 



    Выборка = Запрос.Выполнить().Выбрать(); 


    Пока Выборка.Следующий() Цикл 
        //Колонка цена добавлена в список руками 
        Соответствие.Получить(Выборка.Номенклатура.Ссылка).Ячейки.цена.Значение = Строка(Выборка.Цена) + " " +Выборка.валюта; 
    КонецЦикла; 
КонецПроцедуры

Все норм работает, попробуйте

[nazarenko]

СУПЕР!

ВСЕ РАБОТАЕТ!!!

Даже наименование валюты выводит,
и еще и поиск типа цены по наименованию (что оч. удобно)!

БОЛЬШОЕ СПАСИБО!!!

Всем спасибо! )))