[Vofka]

Привет!

Есть в коде строчка

Значение = ВосстановитьЗначение(сКлюч);

Откуда конкретно восстанавливается это значение?
Т.е. в моей ситуации таким образом определяется тип цен для клиента. Но возникла проблема, что такой тип цен для него никогда не устанавливался и то что оно тянет - не правильно

[Zaval]

Ищи в том же модуле строчки СохранитьЗначение(...,...)
Обычно при закрытии формы сохраняются значения, прописанные в этих строчках, набор этих значений подвязывается к текущему юзеру и доступен только ему.
Походу, в прошлый раз работая с этой формой(объектом), месье слегка накосячить изволили))

[Vofka]

Zaval, дело в том, что эта функция вызывается из глобальной процедуры глВосстановитьЗначение.
Обращение к ф-ции происходит так:

глВосстановитьЗначение(, "ОсновнаяКатегорияЦен");

Искал по всей конфе строки
1. глСохранитьЗначение(, "ОсновнаяКатегорияЦен");
2. СохранитьЗначение(, "ОсновнаяКатегорияЦен");
3. ОсновнаяКатегорияЦен

Так вот находится только 3 строка, причем нигде нету, чтобы она сохранялась. Практически везде она глВосстановитьЗначение. Но есть другое:


Что скажите?

[Zaval]

Спешите вы, сударь...
Вот код той функции. Открой в отладчике и поставь останов в строках с моими комментами.

Функция глВосстановитьЗначение(Конт="", сИдентификатор="", ЗначПоУмолчанию=0) Экспорт
Перем сГруппа, Фирма, ДатаЗнач;                 

    // для совместимости с "Торговля+Склад"
    Если сИдентификатор = "ОсновнаяФирма" Тогда
        сИдентификатор = "БазФирма";
    КонецЕсли;    

    Если ТипЗначенияСтр(Конт) = "ГрупповойКонтекст" Тогда
        сГруппа = Конт.Вид();
        Попытка
            // Конт - документ
            Фирма = Конт.Фирма;
            ДатаЗнач = Конт.ДатаДок;
        Исключение
            // Конт - справочник
            Фирма = 0;
            ДатаЗнач = РабочаяДата();
        КонецПопытки;
    ИначеЕсли ТипЗначенияСтр(Конт) = "Справочник" Тогда
        // элемент справочника Фирмы
        сГруппа = Конт.Вид();
        Фирма = Конт;
        ДатаЗнач = РабочаяДата();
    Иначе
        // строка или что-то другое, преобразуем все к строке
        сГруппа = СокрЛП(Строка(Конт));
        Фирма = 0;
        ДатаЗнач = РабочаяДата();
    КонецЕсли;
    // Попытаемся взять значение из справочника Фирмы, если в справочнике есть
    // такой реквизит. Если этот реквизит не пустой, его значение будет использовано
    // при глОбщиеУстановки=1
    ЗначениеИзФирмы = ПолучитьПустоеЗначение();
    Если ПустоеЗначение(Фирма) = 0 Тогда
        // из реквизита объекта (справочника)
        Попытка
            // прочитаем реквизит
            Реквизит = Метаданные.Справочник("Фирмы").Реквизит(сИдентификатор);
            Если Реквизит.Выбран() = 1 Тогда
                // есть такой реквизит...
                Если Реквизит.Периодический = 1 Тогда
                    //... периодический
                    ЗначениеИзФирмы = Фирма.ПолучитьАтрибут(сИдентификатор).Получить(ДатаЗнач);
                Иначе
                    //... обычный
                    ЗначениеИзФирмы = Фирма.ПолучитьАтрибут(сИдентификатор);
                КонецЕсли;
            КонецЕсли;
        Исключение
        КонецПопытки;
    КонецЕсли;
    // сразу попытаемся восстановить значение по ключу
    сКлюч = ?(ПустаяСтрока(сГруппа) = 0, сГруппа+"_", "")+СокрЛП(сИдентификатор);  
    Значение = ВосстановитьЗначение(сКлюч);    // Zaval: Если в правой части будет тип цен, то надо искать "СохранитьЗначение([сКлюч],"
    Если (глОбщиеУстановки = 2) и (ТипЗначенияСтр(Значение) <> "") Тогда
        // оставляем то, что уже получили
    ИначеЕсли ПустоеЗначение(ЗначениеИзФирмы) = 0 Тогда
        // из реквизита объекта (справочника)
        Значение = ЗначениеИзФирмы;
    ИначеЕсли Метаданные.Константа(сИдентификатор).Выбран() = 1 Тогда         // Zaval: выполнится это - будет возвращена Константа
        // берем из константы...
        Если Метаданные.Константа(сИдентификатор).Периодический = 1 Тогда
            // ...периодической
            Значение = Константа.ПолучитьАтрибут(сИдентификатор).Получить(ДатаЗнач);
        Иначе
            // ...обычной
            Значение = Константа.ПолучитьАтрибут(сИдентификатор);
        КонецЕсли;
    КонецЕсли;
    // если все-таки ничего не получили, то используем значение по умолчанию
    Если ПустоеЗначение(Значение) = 1 Тогда
        Значение = ЗначПоУмолчанию;
    КонецЕсли;
    Возврат Значение;
КонецФункции //глВосстановитьЗначение

[сКлюч] - имеется ввиду значение этой переменной при возврате глючного типа цен. Удачи!

[Vofka]

Спасибо, буду разбираться