[Vofka]

Что то вы мудрите ...
ВЫБРАТЬ
ТоварыНаСкладахОстаткиИОбороты.Регистратор КАК Регистратор,
ТоварыНаСкладахОстаткиИОбороты.КоличествоКонечныйОстаток
ИЗ
РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты(, , Регистратор, , ) КАК ТоварыНаСкладахОстаткиИОбороты

УПОРЯДОЧИТЬ ПО
Регистратор

А у меня вообще регистратор не выбирается. Его даже в списке таблиц нету.

тебя есть виртуальная таблица Партии.Остатки

Есть. Но там нету регистратора (партии)!

[Fynjy]

Кнопка параметры виртуальных таблиц ...

[Vofka]

И что мне дает этот запрос?
Сделал так:

но не пойму как эти данные использовать

ЗЫ. моск взорван

[World1С]

Ну, говорил же что одним запросом все это сделать очень сложно, лучше работать с результатом запроса....

[Vofka]

Подробней можно?

[Fynjy]

Списание по партиям
1. Получить список партий - запрос
2. Цикл пока списываемое количество > количества остатка партии
Все ...

[World1С]

+ 100 Fynjy

1.То что у тебя в результате запроса вставь в цикл
2.

Цикл пока списываемое количество > количества остатка партии

3. Внутри цикла делаем движения расход по регистру партии товара

[вомбат]

Процедура ОбработкаПроведения(Отказ, Режим)
	Запрос = Новый Запрос;
	Запрос.Текст =
	"ВЫБРАТЬ
	|	Накл.Номенклатура КАК Номенклатура,
	|	Ост.Партия КАК Партия,
	|	ЕСТЬNULL(Ост.КоличествоОстаток, 0) КАК КолОст,
	|	ЕСТЬNULL(Ост.СуммаОстаток, 0) КАК СуммаОст,
	|	ЕСТЬNULL(Накл.Количество, 0) КАК КолДок,
	|	ЕСТЬNULL(Накл.Сумма, 0) КАК СуммаДок
	|ИЗ
	|	(ВЫБРАТЬ
	|		Док.Номенклатура КАК Номенклатура,
	|		СУММА(Док.Количество) КАК Количество,
	|		СУММА(Док.Сумма) КАК Сумма
	|	ИЗ
	|		Документ.РасходнаяНакладная.Расход КАК Док
	|	ГДЕ
	|		Док.Ссылка = &ПарСсылка
	|	
	|	СГРУППИРОВАТЬ ПО
	|		Док.Номенклатура) КАК Накл
	|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.Партии.Остатки(
	|				&Момент,
	|				Номенклатура В
	|						(ВЫБРАТЬ РАЗЛИЧНЫЕ
	|							Док.Номенклатура
	|						ИЗ
	|							Документ.РасходнаяНакладная.Расход КАК Док
	|						ГДЕ
	|							Док.Ссылка = &ПарСсылка)
	|					И Склад = &Склад) КАК Ост
	|		ПО Накл.Номенклатура = Ост.Номенклатура
	|
	|ДЛЯ ИЗМЕНЕНИЯ
	|	РегистрНакопления.Партии.Остатки
	|
	|УПОРЯДОЧИТЬ ПО
	|	Номенклатура,
	|	Ост.Партия.Дата
	|ИТОГИ
	|	СУММА(КолОст),
	|	СУММА(СуммаОст),
	|	МАКСИМУМ(КолДок),
	|	МАКСИМУМ(СуммаДок)
	|ПО
	|	Номенклатура";
	
	Запрос.УстановитьПараметр("Момент", МоментВремени());
	Запрос.УстановитьПараметр("ПарСсылка", Ссылка);
	Запрос.УстановитьПараметр("Склад", Склад);
	
	РезультатЗапроса = Запрос.Выполнить();
	ВыборкаТоваров = РезультатЗапроса.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам, "Номенклатура");
	
	Пока ВыборкаТоваров.Следующий() Цикл
		Остаток = ВыборкаТоваров.КолОст;
		КолДок = ВыборкаТоваров.КолДок;
		СуммаДок = ВыборкаТоваров.СуммаДок;
		
		Нехватка = КолДок - Остаток;
		Если Нехватка > 0 Тогда
			Сообщить("Нехватка товара " + СокрЛП(ВыборкаТоваров.Номенклатура) + " на складе " + СокрЛП(Склад) + ": " + Нехватка);
			Сообщить("Расходная накладная " + Номер + " от " + Дата + " не проводится!");
			Отказ = Истина;
		КонецЕсли;
		
		НадоСписать = КолДок;
		ВыборкаПартий = ВыборкаТоваров.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
		Пока ВыборкаПартий.Следующий() Цикл
			КолПартии = ВыборкаПартий.КолОст;
			СуммаПартии = ВыборкаПартий.СуммаОст;
			// вычисление количества списания и себестоимости
			Если НадоСписать < КолПартии Тогда
				// списываем часть партии
				КоличествоСп = НадоСписать;
				СебестоимостьСп = СуммаПартии / КолПартии * КоличествоСп;
				НадоСписать = 0;
			Иначе
				КоличествоСп = КолПартии;
				СебестоимостьСп = СуммаПартии;
				НадоСписать = НадоСписать - КолПартии;
			КонецЕсли;
			// движения по регистру партий
			Движение = Движения.Партии.ДобавитьРасход();
			Движение.Период = Дата;
			Движение.Номенклатура = ВыборкаПартий.Номенклатура;
			Движение.Склад = Склад;
			Движение.Партия = ВыборкаПартий.Партия;
			Движение.Количество = КоличествоСп;
			Движение.Сумма = СебестоимостьСп;
			Если НадоСписать = 0 Тогда
				Прервать;
			КонецЕсли;
		КонецЦикла;
	КонецЦикла;	
КонецПроцедуры

Примерно так будет работать.

[вомбат]

Чуть не забыл. Регистр партий нужно поправить - добавить измерение "Партия", ну и движения ПН тоже подправить.

[Vofka]

ВОМБАТ, с добавлением к регистру партии нового измерения - я получил результат запроса какой хотел



Но теперь я не знаю как мне его использовать . Как знать, что в выборке я перешёл к следующему товару?

И по поводу конструкции "В", кто-то может на пальцах объяснить как она работает?

ЗЫ "Може я тупий?" (с) ТНМК

[World1С]

Конструкция запроса "В" - В (Значение), где значение - > тип: Список значений, Результат запроса, Массив.

[Vofka]

Конструкция запроса "В" - В (Значение), где значение - > тип: Список значений, Результат запроса, Массив.

Т.е. если, например, Номенклатура В &СписокНоменклатуры, где СписокНоменклатуры = массв[товар1, товар2, товар3], то Номенклатура = массв[товар1, товар2, товар3] ?

[World1С]

Пример

ВЫБРАТЬ
   Спр.Номенклатура КАК Товар
ИЗ 
   Справочник.Номенклатура КАК Спр
ГДЕ 
   Спр.Номенклатура В (&СписокЗначений)

Запрос.УстановитьПараметр("СписокЗначений", СписокЗначений)

Где СписокЗначений -> Товар1, Товар2, ....... Товар n

Результат такого запроса будет

Товар1 шт.
Товар2 шт.
........
Товар n шт.

За Массив точно не помню но помоему работает

[Vofka]

А так запрос работать не будет:?

ВЫБРАТЬ
   Спр.Номенклатура КАК Товар
ИЗ 
   Справочник.Номенклатура КАК Спр
ГДЕ 
   Спр.Номенклатура = &СписокЗначений

Запрос.УстановитьПараметр("СписокЗначений", СписокЗначений)

[World1С]

Почему, будет работать если элемент списка будет иметь тип СправочникСсылка.Номенклатура

[Vofka]

Почему, будет работать если элемент списка будет иметь тип СправочникСсылка.Номенклатура

и если в списке значений будет только 1 элемент?

Если мы знаем, что СписокЗначений -> Товар1, Товар2, то можно

ВЫБРАТЬ
   Спр.Номенклатура КАК Товар
ИЗ 
   Справочник.Номенклатура КАК Спр
ГДЕ 
   Спр.Номенклатура В (&СписокЗначений)

Запрос.УстановитьПараметр("СписокЗначений", СписокЗначений)

заменить на

ВЫБРАТЬ
   Спр.Номенклатура КАК Товар
ИЗ 
   Справочник.Номенклатура КАК Спр
ГДЕ 
   Спр.Номенклатура = товар1
   ИЛИ Спр.Номенклатура = товар2

Запрос.УстановитьПараметр("СписокЗначений", СписокЗначений)

[World1С]

Только не или а союз "И"

[Vofka]

Вроде немного разъяснилось... Спасибо!

Но вопрос в посте №70 - ещё актуален

[World1С]

Напомни...

[Vofka]

Елки-палки, на 9 постов выше этого

ВОМБАТ, с добавлением к регистру партии нового измерения - я получил результат запроса какой хотел...