Особенности использования свойства ОтображаемоеИмя почтового адреса

Свойство ОтображаемоеИмя объекта ИнтернетПочтовыйАдрес содержит произвольный текст (например, ФИО человека получающего или отправляющего сообщение), сопоставляемый с почтовым адресом. Данное свойство аналогично свойству ИмяОтправителя объекта ИнтернетПочтовоеСообщение, но расширяет для каждого адреса, включая получателей.

В целях сохранения совместимости с предыдущими релизами платформы 1С:Предприятие 8.1, свойство ИмяОтправителя сохранено, но изменен тип свойства Отправитель:оно может принимать как строковые значения, так и значения типа ИнтернетПочтовыйАдрес.

Большим приоритетом для использования в сообщении обладает свойство ИмяОтправителя. Если свойство пустое, то используется свойство ОтображаемоеИмя объекта ИнтернетПочтовыйАдрес, указанного в свойстве Отправитель.
 
Пример

Почта = Новый ИнтернетПочта;
	Профиль = Новый ИнтернетПочтовыйПрофиль;
	Профиль.АдресСервераSMTP = "localhost";
	Почта.Подключиться(Профиль);
		Сообщение = Новый ИнтернетПочтовоеСообщение;
	Сообщение.Тема = "ОтображаемоеИмя и ИмяОтправителя";

	// В данном случае будет использоваться отображаемое имя из
	// свойства ИмяОтправителя, поскольку оно не пустое
	Сообщение.ИмяОтправителя = "Имя Отправителя";
	Сообщение.Отправитель.ОтображаемоеИмя = "Отображаемое Имя";

	// Для задания адреса отправителя можно использовать старый стиль
	// Сообщение.Отправитель = "ivan@foo.bar.ru";
	// но, в целях повышения читабельности, рекомендуется
	// использовать следующий синтаксис
	Сообщение.Отправитель.Адрес = "ivan@foo.bar.ru";
		Сообщение2 = Новый ИнтернетПочтовоеСообщение;
	Сообщение2.Тема = "ОтображаемоеИмя и ИмяОтправителя 2";
	Сообщение2.ИмяОтправителя = "";

	// Поскольку ИмяОтправителя пустое, текстовое представление будет
	// браться из свойства ОтображаемоеИмя
	Сообщение2.Отправитель.ОтображаемоеИмя = "Отображаемое Имя";
	Сообщение2.Отправитель.Адрес = "ivan@foo.bar.ru";
		Получатель = Сообщение.Получатели.Добавить("vp@foo.bar.ru");
	Получатель.ОтображаемоеИмя = "Вениамин Потапович";
		Получатель = Сообщение2.Получатели.Добавить("vp@foo.bar.ru");
	Получатель.ОтображаемоеИмя = "Вениамин Потапович";
		Почта.Послать(Сообщение);
	Почта.Послать(Сообщение2);
	Почта.Отключиться();