Запрос = Новый Запрос;
    Запрос.Текст = 
        "ВЫБРАТЬ
        |    ПоступлениеТоваровУслуг.Проведен,
        |    ПоступлениеТоваровУслуг.Товары.(
        |        Номенклатура.Ссылка КАК НоменклатураСсылка1
        |    )
        |ИЗ
        |    Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары
        |        ЛЕВОЕ СОЕДИНЕНИЕ Документ.ПоступлениеТоваровУслуг КАК ПоступлениеТоваровУслуг
        |        ПО ПоступлениеТоваровУслугТовары.Ссылка = ПоступлениеТоваровУслуг.Ссылка
        |ГДЕ
        |    ПоступлениеТоваровУслугТовары.Номенклатура = &ЧтоЗаменить
        |    И ПоступлениеТоваровУслуг.Проведен = &Проведен";
        
    Запрос.УстановитьПараметр("Проведен", Истина);
    Запрос.УстановитьПараметр("ЧтоЗаменить", ЭтаФорма.ЧтоЗаменить);

    РезультатЗапроса = Запрос.Выполнить();
    
    ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
    
    Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
        Сообщить(ВыборкаДетальныеЗаписи.НоменклатураСсылка1);
    КонецЦикла;

Нужно получить ссылку на ячейку ТЧ через запрос, чтобы в подальшем изменить ее содержимое.
Ошибка: Поле объекта не обнаружено (НоменклатураСсылка1)
Вопрос: Как достучаться до НоменклатураСсылка1
Пробовал так:
- ВыборкаДетальныеЗаписи.НоменклатураСсылка1 - Ошибка: Поле объекта не обнаружено (НоменклатураСсылка1)
- ВыборкаДетальныеЗаписи.Товары.НоменклатураСсылка1 - Ошибка: Поле объекта не обнаружено (НоменклатураСсылка1)
- ВыборкаДетальныеЗаписи.Товары.Номенклатура.Ссылка - Ошибка: Поле объекта не обнаружено (Номенклатура)
- ВыборкаДетальныеЗаписи.Товары.Ссылка - Ошибка: Поле объекта не обнаружено (Ссылка)
- ВВыборкаДетальныеЗаписи.Ссылка - Ошибка: Поле объекта не обнаружено (Ссылка)
В консоли запросов дело выглядит так:

Запрос для этого не подходит, запросом можно найти документ, а затем уже получить ДокументОбъект и в его ТЧ уже менять необходимую строку.
Запросы в 1С не выполняют изменений данных объектов.

Я так и понял, вот решение, если кому понадобиться:

Если ЗначениеЗаполнено(ЭтаФорма.ЧтоЗаменить) И ЗначениеЗаполнено(ЭтаФорма.НаЧтоЗаменить) Тогда
        //{{КОНСТРУКТОР_ЗАПРОСА_С_ОБРАБОТКОЙ_РЕЗУЛЬТАТА
        // Данный фрагмент построен конструктором.
        // При повторном использовании конструктора, внесенные вручную изменения будут утеряны!!!
        
        Запрос = Новый Запрос;
        Запрос.Текст = 
            "ВЫБРАТЬ
            |    ПоступлениеТоваровУслуг.Проведен,
            |    ПоступлениеТоваровУслуг.Товары.(
            |        Номенклатура
            |    ),
            |    ПоступлениеТоваровУслуг.Ссылка
            |ИЗ
            |    Документ.ПоступлениеТоваровУслуг КАК ПоступлениеТоваровУслуг
            |ГДЕ
            |    ПоступлениеТоваровУслуг.Проведен = &Проведен
            |    И ПоступлениеТоваровУслуг.Товары.Номенклатура = &Номенклатура";
        
        Запрос.УстановитьПараметр("Номенклатура", ЭтаФорма.ЧтоЗаменить);
        Запрос.УстановитьПараметр("Проведен", Истина);
        
        РезультатЗапроса = Запрос.Выполнить();
        
        ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
        
        СчетчикДокументов = 0;
        СчетчикТоваров = 0;
        
        Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
            // Вставить обработку выборки ВыборкаДетальныеЗаписи
            Сообщить("1");
            ДокументПоступлениеТоваровУслуг = ВыборкаДетальныеЗаписи.Ссылка.ПолучитьОбъект();
            Для Каждого СтрокаТабличнойЧасти Из ДокументПоступлениеТоваровУслуг.Товары Цикл
                Если СтрокаТабличнойЧасти.Номенклатура = ЭтаФорма.ЧтоЗаменить Тогда
                    СтрокаТабличнойЧасти.Номенклатура = ЭтаФорма.НаЧтоЗаменить;
                    СчетчикТоваров = СчетчикТоваров + 1;
                КонецЕсли;
            КонецЦикла;
            ДокументПоступлениеТоваровУслуг.Записать();
        СчетчикДокументов = СчетчикДокументов + 1;
        КонецЦикла;
        //}}КОНСТРУКТОР_ЗАПРОСА_С_ОБРАБОТКОЙ_РЕЗУЛЬТАТА
        Сообщить("Заменено " + СчетчикТоваров + " товаров в " + СчетчикДокументов + " документах.");
    Иначе
        Сообщить("Заполните все поля!!!");
    КонецЕсли;

Думаю, перебирать весь документ для "СтрокаТабличнойЧасти.Номенклатура = ЭтаФорма.ЧтоЗаменить" не стоит, запоросом можно получить нужные номера строк и затем сразу работать с нужными строками.

upd: в запросе работайте с табличной частью а не с документом.

MrLOLs, ЛЕВОЕ СОЕДИНЕНИЕ из запроса можно убрать. А добраться к свойству Проведен можно через ПоступлениеТоваровУслугТовары.Ссылка.Проведен.

Запрос.Текст = 
"ВЫБРАТЬ
|    ПоступлениеТоваровУслугТовары.Номенклатура КАК Номенклатура,
|   ПоступлениеТоваровУслуг.Ссылка
|ИЗ
|    Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары
|ГДЕ
|    ПоступлениеТоваровУслуг.Ссылка.Проведен
|    И ПоступлениеТоваровУслуг.Товары.Номенклатура = &Номенклатура
|";

Дал маху в коде, надеюсь, автор темы поймёт это как направление и не буквально.