Заказы на доработку 1С (сервис удаленной работы)

Хранилище

База знаний
Бесплатные отчеты, обработки, конфигурации, внешние компоненты для 1С Статьи, описание работы, методики по работе с 1С

Здравствуйте, гость ( Вход | Зарегистрироваться )



> Функция Формат в языке 1С 8.3, 8.2 (в примерах)          
Vofka Подменю пользователя
сообщение 08.04.15, 10:38
Сообщение #1

У нас здесь своя атмосфера...
***********
Группа: Основатель
Сообщений: 13948
Из: Киев
Спасибо сказали: 4514 раз
Рейтинг: 3635.6

Процедура КнопкаВыполнитьНажатие(Кнопка)

    /// Как указать общее число цифр в 1с 8.3, 8.2

    Сообщить(Формат(125, "ЧЦ=2")); // 99
    Сообщить(Формат(125, "ЧЦ=1")); // 9

    /// Как указать число цифр после запятой в 1с 8.3, 8.2

    Сообщить(Формат(125.368, "ЧДЦ=2")); // 125.37
    Сообщить(Формат(125.368, "ЧДЦ=1")); // 125.4

    /// Как сдвинуть разряды числа в 1с 8.3, 8.2

    Сообщить(Формат(2, "ЧС=1")); // 0,2
    Сообщить(Формат(2, "ЧС=-2")); // 200

    /// Как задать разделитель целой и дробной части в 1с 8.3, 8.2

    Сообщить(Формат(125.36, "ЧРД=///")); // 125///36

    /// Как задать разделитель групп в 1с 8.3, 8.2

    Сообщить(Формат(10000000, "ЧРГ=*")); // 10*000*000

    /// Как задать нулевое представление числа в 1с 8.3, 8.2

    Сообщить(Формат(0, "ЧН=ноль")); // ноль

    /// Как заставить выводить лидирующие нули в 1с 8.3, 8.2

    Сообщить(Формат(125, "ЧЦ=10; ЧВН=")); // 0 000 000 125
    Сообщить(Формат(5, "ЧЦ=2; ЧВН=")); // 05

    /// Как отключить группировку разрядов при выводе числа
    /// в 1с 8.3, 8.2

    Сообщить(Формат(1000000, "ЧГ=0")); // 1000000

    /// Как получить отдельные компоненты даты при выводе
    /// в 1с 8.3, 8.2

    Дата = '20050101200103'; // 01 января 2005 года 20:01:03

    // год
    Сообщить(Формат(Дата, "ДФ=г")); // 5
    Сообщить(Формат(Дата, "ДФ=гг")); // 05
    Сообщить(Формат(Дата, "ДФ=гггг")); // 2005

    // номер квартала
    Сообщить(Формат(Дата, "ДФ=к")); // 1

    // месяц
    Сообщить(Формат(Дата, "ДФ=М")); // 1
    Сообщить(Формат(Дата, "ДФ=ММ")); // 01
    Сообщить(Формат(Дата, "ДФ=МММ")); // янв.
    Сообщить(Формат(Дата, "ДФ=ММММ")); // Январь

    // день
    Сообщить(Формат(Дата, "ДФ=д")); // 1
    Сообщить(Формат(Дата, "ДФ=дд")); // 01
    Сообщить(Формат(Дата, "ДФ=ддд")); // Сб
    Сообщить(Формат(Дата, "ДФ=дддд")); // суббота

    // час
    Сообщить(Формат(Дата, "ДФ=ч")); // 8
    Сообщить(Формат(Дата, "ДФ=чч")); // 08
    Сообщить(Формат(Дата, "ДФ=Ч")); // 20
    Сообщить(Формат(Дата, "ДФ=ЧЧ")); // 20

    // минута
    Сообщить(Формат(Дата, "ДФ=м")); // 1
    Сообщить(Формат(Дата, "ДФ=мм")); // 01

    // секунда
    Сообщить(Формат(Дата, "ДФ=с")); // 3
    Сообщить(Формат(Дата, "ДФ=сс")); // 03

    /// Как задать локальный формат даты при выводе в 1с 8.3, 8.2

    Сообщить(Формат(Дата, "ДЛФ=Д")); // 01.01.2005
    Сообщить(Формат(Дата, "ДЛФ=ДД")); // 1 января 2005 г.
    Сообщить(Формат(Дата, "ДЛФ=В")); // 20:01:03
    Сообщить(Формат(Дата, "ДЛФ=ДДВ")); // 1 января 2005 г. 20:01:03
    Сообщить(Формат(Дата, "ДЛФ=ДВ")); // 01.01.2005 20:01:03

    /// Как задать нулевое представление даты при выводе в 1с 8.3, 8.2

    Сообщить(Формат('00010101000000', "ДП=""пустая дата""")); // пустая дата

    /// Как задать представление значения типа Булево
    /// при выводе в 1с 8.3, 8.2

    Сообщить(Формат(Ложь, "БЛ=""врёшь!""")); // врёшь!
    Сообщить(Формат(Истина, "БИ=""правду говоришь""")); // правду говоришь

    /// Как задать представление периода при выводе в 1с 8.3, 8.2

    Сообщить(
        ПредставлениеПериода(
            НачалоКвартала(ТекущаяДата()),
            КонецКвартала(ТекущаяДата()),
            "ФП=Истина")); // 3 кв. 2013 г., влияет, если 6 или 9 месяцев

    /// Как задать число прописью при выводе в 1с 8.3, 8.2

    Сообщить(
        ЧислоПрописью(123.65)
    );  // Сто двадцать три  65

    Сообщить(
        ЧислоПрописью(
          123.65,,
          "рубль, рубля, рублей, м, копейка, копейки, копеек, ж, 2")
    );  // Сто двадцать три рубля 65 копеек

КонецПроцедуры


[необходимо зарегистрироваться для просмотра ссылки]

Спасибо сказали: dqwerty, melser, python, Sergio_zab,

Petre Подменю пользователя
сообщение 08.04.15, 12:48
Сообщение #2

Живет на форуме
Иконка группы
Группа: Местный
Сообщений: 2903
Из: Київ, Україна
Спасибо сказали: 1144 раз
Рейтинг: 1225

В копилку формат даты с днем в кавычках:
Формат(МояДата, "ДФ = '''""''дд''""'' ММММ гггг'"); // "08" квітня 2015
Формат(МояДата, "ДФ = '''""''дд''""'' ММММ гггг'' р.'''"); // "08" квітня 2015 р.


Сообщение отредактировал Vofka - 08.04.15, 13:22


Signature
Допрацьовую:
- "Бухгалтерія для України 2.1";
- "Альфа-Авто: Автосалон+Автосервіс+Автозапчастини, українська версія".

Спасибо сказали: melser, oleg2020, Vofka,

Не нашли ответа на свой вопрос?
Зарегистрируйтесь и задайте новый вопрос.


Ответить Новая тема
1 чел. читают эту тему (гостей: 1, скрытых пользователей: 0)
Пользователей: 0

 

RSS Текстовая версия Сейчас: 29.03.24, 8:42
1С Предприятие 8.3, 1С Предприятие 8.2, 1С Предприятие 8.1, 1С Предприятие 8.0, 1С Предприятие 7.7, Литература 1С, Общие вопросы по администрированию 1С, Методическая поддержка 1С - всё в одном месте: на Украинском 1С форуме!