[andrew76]

Добрый день !

На форме имеется поле списка.В заполненном списке имеется список контрагентов.
В списке несколько десятков контрагентов.Задачка состоит в следующем-пользователь
может выбрать все контрагенты из списка ("галочка-Checked" включена), или нужные на его взгляд,т.е.
выборочно.Как правильно передать из списка значений выбранные контрагенты в запрос на выборку данных?

У меня выходит что-то вроде нижеследующего:

СтаршийИндекс = ПолеСписка1.Количество() - 1; 
стр="";
Для Сч = 0 по СтаршийИндекс Цикл 
    Если ПолеСписка1[Сч].Пометка=Истина Тогда
         стр=стр+"|И (Контрагент=&"+ПолеСписка1[Сч].Представление+Символы.ПС;
    КонецЕсли;     
КонецЦикла;

Вопрос- как "научить" этот код , чтобы в строку стр передавался параметр ПолеСписка1[Сч].Представление как Объект ?

[logist]

как "научить" этот код

Лучше придумайте как сделать этот код оптимальным, учить его не надо.

Например

Массив = Новый Массив;
Для Каждого Элемент Из Список Цикл
    Если Элемент.Пометка Тогда
        Массив.Добавить(Элемент.Значение);
    КонецЕсли;
КонецЦикла;

Запрос = Новый Запрос("ВЫБРАТЬ
                      |    Контрагенты.Ссылка
                      |ИЗ
                      |    Справочник.Контрагенты КАК Контрагенты
                      |ГДЕ
                      |    Контрагенты.Ссылка В(&Ссылка)");
Запрос.УстановитьПараметр("Ссылка", Массив);

[andrew76]

За идею Спасибо ("палец нажал"),но в процессе её реализации возникли некоторые проблемы:

Во время считывания элементов списка в массив попадают уже элементы с типом "Строка".
Я этот вопрос решил так : Нахожу в справочнике контрагентов нужный элемент по наименованию,
и получаю объект этой записи (ПолучитьОбъект()).

Массив = Новый Массив;
Для Каждого Элемент Из Список Цикл
    Если Элемент.Пометка Тогда
           Об=ВидР.НайтиПоНаименованию(Элемент.Представление).ПолучитьОбъект();
           Массив.Добавить(Об);
    КонецЕсли;
КонецЦикла;

Сам запрос :

Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
|Отгрузка.Ссылка КАК Ссылка, 
|Отгрузка.НомерВ КАК НомерВ,
|Отгрузка.Количество  КАК Количество,
|Отгрузка.ВидРеализации КАК ВидРеализации
|ИЗ
|  Документ.Отгрузка КАК Отгрузка
|ГДЕ
| (Отгрузка.Дата>=&ДатаНач) И (Отгрузка.Дата<=&ДатаКон)";

Условие Ругается на неверные параметры:

Запрос.Текст = Запрос.Текст +"
           |И (Отгрузка.ВидРеализации.Ссылка В(&Ссылка))";   
Запрос.УстановитьПараметр("Ссылка", Массив);

[logist]

Об=ВидР.НайтиПоНаименованию(Элемент.Представление).ПолучитьОбъект();

Получать Объект не нужно, запросу нужен массив ссылок, а вы передаете туда массив объектов.

    Если Элемент.Пометка Тогда
Если ТипЗнч(Элемент.Значение) = Тип("Строка") Тогда
           Массив.Добавить(ВидР.НайтиПоНаименованию(Элемент.Представление));
Иначе
           Массив.Добавить(Элемент.Значение);
КонецЕсли;
    КонецЕсли;

[andrew76]

Не совсем понял, у меня в запросе на заполнение элементов Списка -Значение -это выражение Контрагент.Код,а представление -это выражение Контрагент.Наименование,3-й параметр -это
"галка" -тип Логический.

[logist]

у меня в запросе на заполнение элементов Списка -Значение -это выражение Контрагент.Код

Извините, обычно это ссылка, вообще не понятно зачем Вы туда код пихаете. Только по этой причине там есть тип Строка? Т.е. если сделать по правильному - значение = ссылка, то строкового типа там не будет?

[andrew76]

"Пихаю" ,потому что не знаю как правильно это делать.На то и форум,чтобы спрашивать...
Тип строка в Представлении- это Наименование контрагента.А что Вы мне посоветуете написать
в выражении Значение ? Что-то вроде : СписокЗначений.Значение=Контрагент.Ссылка ?

[logist]

"Пихаю" ,потому что не знаю как правильно это делать.На то и форум,чтобы спрашивать...

Если не знаете как правильно, то надо выкладывать максимум информации о задаче.

ип строка в Представлении- это Наименование контрагента.А что Вы мне посоветуете написать
в выражении Значение ? Что-то вроде : СписокЗначений.Значение=Контрагент.Ссылка ?

Покажите процедуру заполнения списка.

[andrew76]

Процедура заполнения списка:

Запрос = Новый Запрос();
Запрос.Текст= " 
|ВЫБРАТЬ 
|    ВидРеализации.Код КАК Значение, 
|    ВидРеализации.ССылка КАК Представление, 
|    ЛОЖЬ КАК Пометка 
|ИЗ 
|    Справочник.ВидРеализации КАК ВидРеализации
|
|УПОРЯДОЧИТЬ ПО
|    ВидРеализации.Наименование";
    

Выборка = Запрос.Выполнить().Выбрать(); 

Пока Выборка.Следующий() Цикл 
     ЗаполнитьЗначенияСвойств(ПолеСписка1.Добавить(), Выборка); 
КонецЦикла;

[logist]

Запрос = Новый Запрос();
Запрос.Текст= " 
|ВЫБРАТЬ 
|    ВидРеализации.Ссылка
|ИЗ 
|    Справочник.ВидРеализации КАК ВидРеализации
|
|УПОРЯДОЧИТЬ ПО
|    ВидРеализации.Наименование";
    
ПолеСписка1.ЗагрузитьЗначения(Запрос.Выполнить().Выгрузить().ВыгрузитьКолонку("Ссылка"));

В этом случае пример запроса который я написал в самом начале (сообщение #2) будет корректно работать.
У вас, похоже, не хватает базовых знаний, займитесь этим, а то вы изобретаете велосипед с квадратными колесами

[andrew76]

Что есть ,то- есть.