[valera_avp]

И снова здрасте!
Опять возникла проблема.
Для поиска документов для которых текущий является основанием использовал поиск по номеру документа, но как выяснилось нумерация документов ведется в пределах года соответственно искать нужно по сочетанию номер дата, сделал следующим образом:

Запрос = Новый Запрос;
        Запрос.Текст = 
            "ВЫБРАТЬ
            |    РеализацияТоваровУслуг.Сделка.Номер КАК СделкаНомер1,
            |    ЗаказНаПроизводствоПродукция.Заказ.Номер,
            |    НалоговаяНакладная.Сделка.Номер
            |ИЗ
            |    Документ.НалоговаяНакладная КАК НалоговаяНакладная
            |        ПОЛНОЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
            |            ПОЛНОЕ СОЕДИНЕНИЕ Документ.ЗаказНаПроизводство.Продукция КАК ЗаказНаПроизводствоПродукция
            |            ПО (ЗаказНаПроизводствоПродукция.Заказ.Номер = РеализацияТоваровУслуг.Сделка.Номер)
            |        ПО (РеализацияТоваровУслуг.Сделка.Номер = НалоговаяНакладная.Сделка.Номер)
            |ГДЕ
            |    ЗаказНаПроизводствоПродукция.Заказ.Дата = &Дата
            |    И НалоговаяНакладная.Сделка.Дата = &Дата
            |    И РеализацияТоваровУслуг.Сделка.Дата = &Дата";
        Запрос.УстановитьПараметр("Дата", ЭтотОбъект.Дата);
        Выборка = Запрос.Выполнить().Выбрать();

неработает, причем если брать без условий то все в порядке (если не считать кучу документов с одинаковыми номерами за разные периоды) Кто нить знает в чем проблема?

[logist]

А реквизит ДокументОснвоание уже отменили? Этот Ваш запрос найдет всё что угодно, но не то,что надо, выкиньте его, и больше никому не показывайте.

[valera_avp]

А реквизит ДокументОснвоание уже отменили? Этот Ваш запрос найдет всё что угодно, но не то,что надо, выкиньте его, и больше никому не показывайте.

в документах РеализацияТоваровУслуг и НалоговаяНакладная документ-основание прописывается в реквизите Сделка, а в документе ЗаказНаПроизводство документ-основание прописывается в табличной части

[logist]

в документах РеализацияТоваровУслуг и НалоговаяНакладная документ-основание прописывается в реквизите Сделка, а в документе ЗаказНаПроизводство документ-основание прописывается в табличной части

Ну и? В чем проблема?

[valera_avp]

проблема в этом

но как выяснилось нумерация документов ведется в пределах года соответственно искать нужно по сочетанию номер дата

если убираю этот кусок

   |ГДЕ
            |    ЗаказНаПроизводствоПродукция.Заказ.Дата = &Дата
            |    И НалоговаяНакладная.Сделка.Дата = &Дата
            |    И РеализацияТоваровУслуг.Сделка.Дата = &Дата";
        Запрос.УстановитьПараметр("Дата", ЭтотОбъект.Дата);

все работает нормально, но выдает номера документов за весь период и соответственно номера повторяются

может подскажете варианты как отсеять все документы не текущего года создания\проведения

[Vofka]

Может так?

        Запрос = Новый Запрос;
        Запрос.Текст = 
            "ВЫБРАТЬ
            |    РеализацияТоваровУслуг.Сделка.Номер КАК СделкаНомер1,
            |    ЗаказНаПроизводствоПродукция.Заказ.Номер,
            |    НалоговаяНакладная.Сделка.Номер
            |ИЗ
            |    Документ.НалоговаяНакладная КАК НалоговаяНакладная
            |        ПОЛНОЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
            |            ПОЛНОЕ СОЕДИНЕНИЕ Документ.ЗаказНаПроизводство.Продукция КАК ЗаказНаПроизводствоПродукция
            |            ПО (ЗаказНаПроизводствоПродукция.Заказ.Номер = РеализацияТоваровУслуг.Сделка.Номер)
            |        ПО (РеализацияТоваровУслуг.Сделка.Номер = НалоговаяНакладная.Сделка.Номер)
            |ГДЕ
            |    ЗаказНаПроизводствоПродукция.Заказ.Дата < &Дата
            |    И НалоговаяНакладная.Сделка.Дата < &Дата
            |    И РеализацияТоваровУслуг.Сделка.Дата < &Дата";
        Запрос.УстановитьПараметр("Дата", НачалоГода(ЭтотОбъект.Дата));
        Выборка = Запрос.Выполнить().Выбрать();

ПС. особо не вникал в логику запроса

Сообщение отредактировал Vofka - 26.04.13, 16:34

[valera_avp]

Не совсем понял конструкцию

 |    И РеализацияТоваровУслуг.Сделка.Дата < &Дата";
        Запрос.УстановитьПараметр("Дата", НачалоГода(ЭтотОбъект.Дата));

но это неважно потому что все равно не работает

[Petre]

Все что в "ГДЕ" надо перенести в секцию "ПО", иначе полное соединение превращается во внутреннее.

[valera_avp]

Все что в "ГДЕ" надо перенести в секцию "ПО", иначе полное соединение превращается во внутреннее.

не совсем понял суть можно примерчик

[logist]

Ребята, я не пойму чего вы привязались к этим номерам? Завтра пойдет сбой номеров и документы не будут совпадать что тогда? Работайте с ДокументОснование.

[Petre]

не совсем понял суть можно примерчик

Что-то типо того:

    Запрос = Новый Запрос;
    Запрос.Текст = 
            "ВЫБРАТЬ
            |    РеализацияТоваровУслуг.Сделка.Номер КАК СделкаНомер1,
            |    ЗаказНаПроизводствоПродукция.Заказ.Номер,
            |    НалоговаяНакладная.Сделка.Номер
            |ИЗ
            |    Документ.НалоговаяНакладная КАК НалоговаяНакладная
            |        ПОЛНОЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
            |            ПОЛНОЕ СОЕДИНЕНИЕ Документ.ЗаказНаПроизводство.Продукция КАК ЗаказНаПроизводствоПродукция
            |            ПО (ЗаказНаПроизводствоПродукция.Заказ.Номер = РеализацияТоваровУслуг.Сделка.Номер)
            |                И (ЗаказНаПроизводствоПродукция.Заказ.Дата = &Дата)
            |                И (РеализацияТоваровУслуг.Сделка.Дата = &Дата)
            |        ПО (РеализацияТоваровУслуг.Сделка.Номер = НалоговаяНакладная.Сделка.Номер)
            |            И (РеализацияТоваровУслуг.Сделка.Дата = &Дата)
            |            И (НалоговаяНакладная.Сделка.Дата = &Дата)";
    Запрос.УстановитьПараметр("Дата", ЭтотОбъект.Дата);
    Выборка = Запрос.Выполнить().Выбрать();

[valera_avp]

Я просто немогу понять что значит

Работайте с ДокументОснование.

У меня есть документ РеализацияТоваровУслуг у которого в поле Сделка прописано что основанием для этого документа является ЗакакПопупателя, как мне при перепроведении ЗаказПокупателя проверить что на его основании создан документ РеализацияТоваровУслуг и запретить перепроведение документа ЗаказПокупателя!!!

[logist]

типа такого

// вставить в ОбработкаПроведения заказа
Запрос = Новый Запрос("ВЫБРАТЬ ПЕРВЫЕ 1
                      |    РеализацияТоваровУслуг.Ссылка
                      |ИЗ
                      |    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
                      |ГДЕ
                      |    РеализацияТоваровУслуг.Сделка = &ДокументОснование");
Запрос.УстановитьПараметр("ДокументОснование", Ссылка); // Это ссылка на заказ (т.е. текущий док)
Результат = Запрос.Выполнить();
Отказ = Не Результат.Пустой(); // если найдется хоть одна накладная - это вызовет отмену проведения.

[valera_avp]

Сделал ПОЧТИ так как советовал logist ПОЛУЧИЛОСЬ!!!!
Текст выкладывать небуду, потому что ну ОСЕНЬ СТРАШНЫЙ получился (раскритикуете в пух и прах)
Всем спасибо за участие!!!!

[logist]

(раскритикуете в пух и прах)

А почему Вы боитесь критики? Ведь вам укажут на ошибки, которые вы в будущем можете избежать.

[Vofka]

logist, я на форуме когда-то уже выкладывал это:

[logist]

я на форуме когда-то уже выкладывал это:

Это понятно, но ведь надо же подсказать человеку, что ничего страшного в этом нет. Тем более человек старается, что-то делает, а не приходит на форум с фразой "напишите мне код".

[valera_avp]

Ну как-то так

    Если РольДоступна("МенеджерПоПродажам1") Тогда        
        Запрос = Новый Запрос;
        Запрос.Текст = 
            "ВЫБРАТЬ
            |    РеализацияТоваровУслуг.Ссылка,
            |    НалоговаяНакладная.Ссылка КАК Ссылка1,
            |    ЗаказНаПроизводствоПродукция.Ссылка КАК Ссылка2,
            |    ЗаказПокупателя.Ссылка КАК Ссылка3
            |ИЗ
            |    Документ.ЗаказПокупателя КАК ЗаказПокупателя
            |        ЛЕВОЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
            |        ПО (РеализацияТоваровУслуг.Сделка = ЗаказПокупателя.Ссылка)
            |        ЛЕВОЕ СОЕДИНЕНИЕ Документ.НалоговаяНакладная КАК НалоговаяНакладная
            |        ПО (НалоговаяНакладная.Сделка = ЗаказПокупателя.Ссылка)
            |        ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЗаказНаПроизводство.Продукция КАК ЗаказНаПроизводствоПродукция
            |        ПО (ЗаказНаПроизводствоПродукция.Заказ = ЗаказПокупателя.Ссылка)
            |ГДЕ
            |    (ЗаказНаПроизводствоПродукция.Заказ = &Сделка
            |            ИЛИ НалоговаяНакладная.Сделка = &Сделка
            |            ИЛИ РеализацияТоваровУслуг.Сделка = &Сделка)";
        Запрос.УстановитьПараметр("Сделка",ЭтотОбъект.Ссылка);
        Выборка = Запрос.Выполнить().Выбрать();
        
        Если  Выборка.НайтиСледующий(ЭтотОбъект.Ссылка,"Ссылка3") 
            Тогда Отказ = Истина;
            Сообщить("Документ является основанием для "
            + Выборка.Ссылка 
            + Выборка.Ссылка1 
            + Выборка.Ссылка2);
            Сообщить("Перепроведение документа ЗАПРЕЩЕНО!");
        КонецЕсли;
    КонецЕсли;

logist спасибо за поддержку

[valera_avp]

И что никто ничего не напишет. Где критика? Или я гений

[Ardi]

1.

    Массив = Новый Массив;
    Массив.Добавить(ЭтотОбъект.Ссылка);
    
    ТабСсылок = НайтиПоСсылкам(Массив);
    Для Каждого Ссылка из ТабСсылок Цикл
        Сообщить ("" + СокрЛП(Ссылка[0]) + "  " + СокрЛП(Ссылка[1]));
    КонецЦикла;

2.

    ТекстЗапроса = 
                     "ВЫБРАТЬ
       |    НалоговаяНакладная.Ссылка
       |ИЗ
       |    Документ.НалоговаяНакладная КАК НалоговаяНакладная
       |ГДЕ
       |    НалоговаяНакладная.ДокументОснование = &Сделка
       |
       |ОБЪЕДИНИТЬ ВСЕ
       |
       |ВЫБРАТЬ
       |    РеализацияТоваровУслуг.Ссылка
       |ИЗ
       |    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
       |ГДЕ
       |    РеализацияТоваровУслуг.Сделка = &Сделка"

Сообщение отредактировал Ardi - 29.04.13, 18:19