1с8.3 Самописная. Клиент-сервер.
Добрый день, Уважаемое сообщество.
Столкнулся с вопросом. Как запретить пользователю отменять проводку (програмно), не используя роли?

Сообщение отредактировал l2d808 - 13.08.18, 11:12

l2d808 @ Сегодня, 12:10 ,
Если всем пользователем то ПередЗаписью проверять РежимЗаписи если ОтменаПроведения то Отказ, а если нужны условия то нужо выкручивваться с них.

Вышел с ситуации так:

в модуле документа прописал:

Процедура ОбработкаУдаленияПроведения(Отказ)
    Сообщить("Відміна проведення ЗАБОРОНЕНА! Зверніться до Адміністратора!");
    Отказ = Истина;
КонецПроцедуры

Если кому интересно, дальше можно ставить любое условие.

Сообщение отредактировал l2d808 - 13.08.18, 13:50

Есть продолжение данной темы.
Как запретить програмно обычное и интерактисное удаление справочников и документов?

Трудно добавить роль?
Или "делаем ректально" - это наше второе Я ?

sava1 @ Сегодня, 11:10 ,
Суть в том что, роли раздаются направо и налево, а вот некоторые объекты должны быть стабильно не изменяемые.
А вот на счет "ректально" пожалуйста поподробнее...

В модуле объекта обработчик ПередУдалением()

Процедура ПередУдалением(Отказ)
    Если Не РольДоступна ("СуперПуперАдминистратор") Тогда
        Отказ = Истина;
    КонецЕсли;
КонецПроцедуры

То же добавить и в приведенный выше код:

Процедура ОбработкаУдаленияПроведения(Отказ)
    Если Не РольДоступна ("СуперПуперАдминистратор") Тогда
        Сообщить("Відміна проведення ЗАБОРОНЕНА! Зверніться до Адміністратора!");
        Отказ = Истина;
    КонецЕсли;
КонецПроцедуры

Ответственным пользователям, которым разрешено помечать на удаление указанные объекты добавить роль "СуперПуперАдминистратор".
А вот что делать с обработкой удаления объектов с ИТС или из меню Операции - Удаление помеченных объектов - отобрать право "интерактивное удаление объектов".

К сожалению при попытке пометить на удаление, реакции никакой. эту процедуру при удалении 1с-ка не замечает.

Пометка на удаление - это не удаление, а просто запись документа с доп. реквизитом IsMarked.
Анализироват надо перед записью - сравнивать объект и объектВбазе. И в случае пометки - отказываться от записи.

l2d808 @ Вчера, 14:06 ,

В модуле объекта

Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)
      Если ПометкаУдаления 
        И Не Ссылка.ПометкаУдаления
        И Не РольДоступна ("СуперПуперАдминистратор") Тогда
        
        Отказ = Истина;
      КонецЕсли;
КонецПроцедуры

ed.kharkov @ 15.08.18, 11:40 ,
Можно ли эту процедуру создать в общем модуле и применить для всех объектов "Документы" чтоб не писать в каждом отдельно ??

Можно создать подписку на событие

Slon747 @ Сегодня, 20:30 ,
Если возможно, то опишите метод по подробнее, с примером будет лучше))))

Вот пример из типовой конфигурации.
В данном примере перед записью любого типа документа (источник ДокументОбъект) вызывается процедура общего модуля и там можно вызвать Отказ.

Процедура ПередЗаписьюДокументаДатаЗапретаРедактированияПередЗаписью(Источник, Отказ, РежимЗаписи, РежимПроведения) Экспорт
    
    Если Отказ ИЛИ Источник.ОбменДанными.Загрузка Тогда
        Возврат;
    КонецЕсли;

    Если    ТипЗнч(Источник) = Тип("ДокументОбъект.ВыгрузкаРегламентированныхОтчетов")
        ИЛИ ТипЗнч(Источник) = Тип("ДокументОбъект.РегламентированныйОтчет") Тогда
        // для этих типов документов не проверяем.
        Возврат;
    КонецЕсли;
    
    ПроверкаПериодаДокумента(Источник, Отказ, РежимЗаписи);
    Если Отказ Тогда
        #Если Клиент Тогда
            Сообщить(НСтр("ru='Редактирование данных этого периода запрещено. Изменения не могут быть записаны...';uk='Редагування даних цього періоду заборонено. Зміни не можуть бути записані...'"), СтатусСообщения.Важное);
        #КонецЕсли
    КонецЕсли;
КонецПроцедуры // ПередЗаписьюДокументаДатаЗапретаРедактированияПередЗаписью()

Slon747 @ Вчера, 9:58 ,
Благодарю !!! ваш совет помог, только вот как написать метод на условие ПометкаУдаления?

в модуле объекта так работает, а как вызвать из общего модуля такой метод? (ПометкаУдаления, Ссылка)

    Если ПометкаУдаления 
        И Не Ссылка.ПометкаУдаления
        И Не РольДоступна ("ПолныеПрава") Тогда
        Сообщить("У вас не достаточно прав на удаление!");
        Отказ = Истина;
    КонецЕсли;

Сообщение отредактировал Vofka - 12.05.25, 15:10

muslim18 @ Сегодня, 11:25 ,
Вот так я сделал. Проверил, работает.

Процедура ПередПометкойНаУдалениеДокумента(Источник, Отказ, РежимЗаписи, РежимПроведения) Экспорт
    
    Если Отказ ИЛИ Источник.ОбменДанными.Загрузка Тогда
        Возврат;
    КонецЕсли;

    Если Источник.ПометкаУдаления И Не Источник.Ссылка.ПометкаУдаления И Не РольДоступна("ПолныеПрава") Тогда
        Сообщить("У вас не достаточно прав на удаление!");
        Отказ = Истина;
    КонецЕсли;

КонецПроцедуры

Slon747 @ 12.05.25, 16:23 ,
Благодарю за поддержку!! получилось реализовать.