Заказы на доработку 1С (сервис удаленной работы)

Хранилище

База знаний
Бесплатные отчеты, обработки, конфигурации, внешние компоненты для 1С Статьи, описание работы, методики по работе с 1С

Здравствуйте, гость ( Вход | Зарегистрироваться )



> Как можно управлять панелями разделов программно          
mikkia Подменю пользователя
сообщение 04.04.24, 14:05
Сообщение #1

Молчаливый
*
Группа: Пользователи
Сообщений: 1
Спасибо сказали: 0 раз
Рейтинг: 0

Пытаюсь сделать это через настройки
НастройкиИнтерфейса = ХранилищеСистемныхНастроек.Загрузить("Общее/ПанельРазделов/НастройкиКомандногоИнтерфейса");

но не знаю какие там методы есть. Через НастройкиИнтерфейса может только скрыть панели, а мне нужно конкретно одну панель скрыть от пользователей.

AnryMc Подменю пользователя
сообщение 04.04.24, 14:27
Сообщение #2

Оратор
Иконка группы
Группа: Местный
Сообщений: 378
Спасибо сказали: 103 раз
Рейтинг: 104.6

mikkia @ Сегодня, 15:05 * ,

Процедура ПриНачалеРаботыСистемы(Отказ)
    
    // Определить размеры экрана.
    Экраны = ПолучитьИнформациюЭкрановКлиента();
    
    // Для примера допускаем, что экран один.
    // Но если экранов несколько, нужно анализировать их все.
    ВысотаЭкрана = Экраны[0].Высота;
    ШиринаЭкрана = Экраны[0].Ширина;
    
    // Если экран маленький, включить только панель инструментов.
    // Если ...
        НастройкаИнтерфейса.ВыполнитьНастройкуПанелей();
    // КонецЕсли;
    
    ОбновитьИнтерфейс();
    
КонецПроцедуры

Процедура ВыполнитьНастройкуПанелей() Экспорт
    
    // Для примера будем менять настройки пользователя "не глядя" на то, что он себе настроил.
    // Создать пустой объект настроек.
    НастройкиИнтерфейса = Новый НастройкиИнтерфейсаКлиентскогоПриложения;
    
    // С помощью пустого объекта настроек получить настройки состава, установленные в конфигураторе.
    НастройкиСостава = НастройкиИнтерфейса.ПолучитьСостав();
    
    // Очистить настройки состава.
    НастройкиСостава.Верх.Очистить();
    НастройкиСостава.Лево.Очистить();
    НастройкиСостава.Низ.Очистить();
    НастройкиСостава.Право.Очистить();
    
    // Заполнить своими панелями.
    // Для примера самый простой вариант: слева - панель инструментов.
    ПанельИнструментов = Новый ЭлементНастройкиСоставаИнтерфейсаКлиентскогоПриложения("ПанельИнструментов");
    НастройкиСостава.Лево.Добавить(ПанельИнструментов);
    
    // Загрузить настройки состава в пустой объект настроек.
    НастройкиИнтерфейса.УстановитьСостав(НастройкиСостава);
    
    // Положить объект настроек текущему пользователю в хранилище.
    ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения", , НастройкиИнтерфейса);

    // Если же хотим менять настройки, которые установил пользователь себе,
    // тогда нужно прочитать его настройки из хранилища, и метод ПолучитьСостав()
    // вернёт не то, что в конфигураторе, а то, что пользователь установил себе.
    //
    // НастройкиИнтерфейса = ХранилищеСистемныхНастроек.Загрузить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения");
    // НастройкиСостава = НастройкиИнтерфейса.ПолучитьСостав();    
    // ... изменть настройки состава
    // НастройкиИнтерфейса.УстановитьСостав(НастройкиСостава);
    // ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения", , НастройкиИнтерфейса);
    
КонецПроцедуры

Не нашли ответа на свой вопрос?
Зарегистрируйтесь и задайте новый вопрос.


Ответить Новая тема
1 чел. читают эту тему (гостей: 1, скрытых пользователей: 0)
Пользователей: 0

 

RSS Текстовая версия Сейчас: 20.07.24, 0:26
1С Предприятие 8.3, 1С Предприятие 8.2, 1С Предприятие 8.1, 1С Предприятие 8.0, 1С Предприятие 7.7, Литература 1С, Общие вопросы по администрированию 1С, Методическая поддержка 1С - всё в одном месте: на Украинском 1С форуме!