Помощь - Поиск - Пользователи - Календарь
Полная версия этой страницы: Окошко с прогресс бар-ом
Украинский 1С форум: всё про 1С 8.3, 1С 8.2, 1С 8.1, 1С 8.0, 1С 7.7 > Программисту > Программирование в 1С Предприятие 8.2 > Программирование управляемых форм 1С 8.2
Fabri
31.08.12, 12:50
Подскажите пожалуйста. Есть необходимость вывода пользователю - прогресс бара либо данных выполнения.

К примеру, есть цикл:

Для А=0 По 50 Цикл
Сообщить(А);
КонецЦикла;


Вместо Сообщить, необходимо б чтобы выводилось окно с прогресс бар-ом или с надписью, пододжиде, выполняется операция № А.

Думал создать общую форму, и её вызывать, так в 8.2 не вижу где добавить элемент прогресс бар на форму. Заранее спасибо.
pablo
31.08.12, 12:59
Прогрессбар - это обычный числовой реквизит, вынесенный на форму, у элемента управления которого Вид = Поле индикатора (в редакторе свойств)

+ еще можно посмотреть типовую общую форму ХодВыполненияОбработкиДанных
ignsv
31.08.12, 13:00
пример через общую форму
мФормаИндикатора = ПолучитьОбщуюФорму("ХодВыполненияОбработкиДанных");
мФормаИндикатора.ВладелецФормы = ЭтаФорма;
Если мФормаИндикатора.Открыта() Тогда
Возврат;
КонецЕсли;
    
мФормаИндикатора.Открыть();

мФормаИндикатора.КомментарийОбработкиДанных = "Разбивка значения на отдельные слова";
мФормаИндикатора.МаксимальноеЗначение = ТаблицаСправочника.Количество();        

Для Каждого СтрокаСсылки ИЗ ТаблицаСправочника Цикл
        
мФормаИндикатора.Значение = ТаблицаСправочника.Индекс(СтрокаСсылки)+1;

Конеццикла;

мФормаИндикатора.Закрыть();
logist
31.08.12, 13:02
Цитата(pablo @ 31.08.12, 13:59) необходимо зарегистрироваться для просмотра ссылки
Прогрессбар - это обычный числовой реквизит

В управляемых формах есть такая штука:

Цитата
Состояние (Status)
Синтаксис:

Состояние(<ТекстСообщения>, <Прогресс>, <Пояснение>, <Картинка>)
Параметры:

<ТекстСообщения> (необязательный)

Тип: Строка.
Строка, предназначенная для вывода в панель состояния. Если параметр не указан, возобновляется вывод системного текста в панель состояния.
<Прогресс> (необязательный)

Тип: Число.
Значение индикатора прогресса (от 1 до 100).
Если не задан, индикатор прогресса не отображается.
<Пояснение> (необязательный)

Тип: Строка.
Текст пояснения.
<Картинка> (необязательный)

Тип: Картинка.
Картинка.
Описание:

Выводит текст в панель состояния.
pablo
31.08.12, 13:05
logist Ваш прогрессбар будет в строке состояния внизу формы (если не ошибаюсь), а мой - в (почти) произвольном месте формы wink.gif
logist
31.08.12, 13:22
Цитата(pablo @ 31.08.12, 14:05) необходимо зарегистрироваться для просмотра ссылки
будет в строке состояния внизу формы (если не ошибаюсь)

Ошибаетесь, он будет в нижнем правом углу экрана не зависимо от окон форм и главного окна приложения smile.gif
Vofka
31.08.12, 13:27
Общая форма из типовых, боюсь, в самописной конфе на управляемых формах не даст нужного эффекта smile.gif
Fabri
31.08.12, 14:53
Вариант logist-а самый реальный, единственный минус что нет возможности установки максимального значения.
Может есть среди формучан умный математик, подсказавший формулу для обчисления шага.
pablo
31.08.12, 15:18
А чего там писать? Передавать в прогресс Окр(100*ТекущееЗначение/МаксимальноеЗначение)
pumbaE
31.08.12, 15:23
Цитата(pablo @ 31.08.12, 16:18) необходимо зарегистрироваться для просмотра ссылки
А чего там писать? Передавать в прогресс Окр(100*ТекущееЗначение/МаксимальноеЗначение)

И главное не забыть все 10000 операций гонять с сервера на клиент форму.

Обработчик ожидания, раз в секунду опрашивает временное хранилище, где хранится текущее состояние , на сервер фоновым заданием выполняем долгоиграющую операцию и во временное хранилище пишем наш прогресс.
logist
31.08.12, 15:29
Может кому пригодится, приведу пример как это реализовано у меня (используется для загрузки больших файлов):
В модуле формы:
        Индикатор = РаботаСЭлектроннымиДокументамиКлиент.ПолучитьИндикаторПроцессаЗагрузки(НомерПервойСтрокиФайла,НомерПоследнейСтрокиФайла,Порция);
        Пока Индикатор.КонСтрока < НомерПоследнейСтрокиФайла Цикл
            РаботаСЭлектроннымиДокументамиКлиент.ПоказатьСостояниеЗаугркзи(Индикатор);
            ПрочитатьПорциюИзФайла(Индикатор.НачСтрока, Индикатор.КонСтрока);
        КонецЦикла;


Общий модуль:
Функция ПолучитьИндикаторПроцессаЗагрузки(НомерПервойСтроки, НомерПоследнейСтроки, Порция, ВыводитьВремя = Истина) Экспорт

    КоличествоЦиклов = ?((НомерПоследнейСтроки-НомерПервойСтроки-1) <= Порция,1,Цел((НомерПоследнейСтроки-НомерПервойСтроки-1)/Порция)+1);
    
    Индикатор = Новый Структура;
    Индикатор.Вставить("ВыводитьВремя", ВыводитьВремя);
    Индикатор.Вставить("РазрешитьПрерывание", Истина);
    Индикатор.Вставить("ДатаНачала", ТекущаяДата());
    Индикатор.Вставить("НачальнаяСтрока", НомерПервойСтроки);
    Индикатор.Вставить("ПоследняяСтрока", НомерПоследнейСтроки);
    Индикатор.Вставить("Порция", Порция);
    Индикатор.Вставить("КоличествоЦиклов", КоличествоЦиклов);

    Индикатор.Вставить("НачСтрока", НомерПервойСтроки);
    Индикатор.Вставить("КонСтрока", НомерПервойСтроки);
    Индикатор.Вставить("Счетчик", 0);
    Возврат Индикатор;

КонецФункции

Процедура ПоказатьСостояниеЗаугркзи(Индикатор) Экспорт
    
    Индикатор.НачСтрока = ?(Индикатор.Счетчик = 0,Индикатор.НачСтрока,Индикатор.КонСтрока+1);
    Индикатор.КонСтрока = ?((Индикатор.НачСтрока + (Индикатор.Порция-1)) < Индикатор.ПоследняяСтрока,Индикатор.НачСтрока + (Индикатор.Порция-1),Индикатор.ПоследняяСтрока);
    
    Если Индикатор.РазрешитьПрерывание Тогда
        ОбработкаПрерыванияПользователя();
    КонецЕсли;
    
    Индикатор.Счетчик = Индикатор.Счетчик + 1;
    
    Если Индикатор.ВыводитьВремя Тогда
        ТекущаяДата = ТекущаяДата();
        ПрошлоВремени = ТекущаяДата - Индикатор.ДатаНачала;
        Осталось = ПрошлоВремени * (Индикатор.КоличествоЦиклов / Индикатор.Счетчик - 1);
        Часов = Цел(Осталось / 3600);
        Осталось = Осталось - (Часов * 3600);
        Минут = Цел(Осталось / 60);
        Секунд = Цел(Цел(Осталось - (Минут * 60)));
        ОсталосьВремени = Формат(Часов, "ЧЦ=2; ЧН=00; ЧВН=") + ":"
        + Формат(Минут, "ЧЦ=2; ЧН=00; ЧВН=") + ":"
        + Формат(Секунд, "ЧЦ=2; ЧН=00; ЧВН=");
        Если Индикатор.КоличествоЦиклов = 1 Тогда
            ТекстОсталось = "Осталось: Немного";
        ИначеЕсли Индикатор.Счетчик <= 1 Тогда
            ТекстОсталось = "Осталось: Неизвестно";
        Иначе
            ТекстОсталось = "Осталось: ~" + ОсталосьВремени;
        КонецЕсли;
    Иначе
        ТекстОсталось = "";
    КонецЕсли;
    
    Если Индикатор.Счетчик > Индикатор.КоличествоЦиклов Тогда
        Состояние("Выполнено",100,"Загрузка окончена. Подождите немного.");
    Иначе
        Состояние("Выполняется загрузка из файла...    "+ТекстОсталось,Цел(Индикатор.Счетчик / Индикатор.КоличествоЦиклов * 100),"Обрабатываются строки с "+Индикатор.НачСтрока+" по "+Индикатор.КонСтрока+", из "+Индикатор.ПоследняяСтрока);
    КонецЕсли;

КонецПроцедуры
pumbaE
31.08.12, 15:45
Прошу прощения за язвительный тон, не прочитал предисторию "Окр(100*ТекущееЗначение/МаксимальноеЗначение)" 05071.gif
Для просмотра полной версии этой страницы, пожалуйста, пройдите по ссылке.