Доброго времени суток! Есть конфигурация УТ 11, в ней есть такой справочник "ПрисоединенныеФайлыНоменклатуры". Я добавил несколько реквизитов А1, А2, А3, А4 - булево. Когда заходишь в предприятие, открываешь элемент справочника номенклатура далее нажать "присоединенные файлы" то открывается как я понимаю общая форма в которой я хочу увидеть эти реквизиты.

Добавил в ДинамическийСписок свои булевские реквизиты, перенес на форму. В конфигураторе на форме колонка есть, а в предприятии нет.

Собственно сам вопрос, это как отобразить в табличной части формы "Присоединенные файлы" добавить колонки с флажками этих реквизитов А1,А2,А3,А4?

смотрим "настройки формы", по идее..
точно та форма что надо открывается?

Вот где надо добавить


Вот что делаю:


Вот что получаю:




Что делаю не так?

кажется понял в чем дело, сейчас попробую...по моему не в ту форму добавил ))



По кнопке "Присоединенные файлы" выполняется такой код общей команды "ПрисоединенныеФайлы":

&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
    Параметры = Новый Структура;
    Параметры.Вставить("ВладелецФайла", ПараметрКоманды);
    Заголовок = НСтр("ru = 'Присоединенные файлы'");
    Параметры.Вставить("ЗаголовокФормы", Заголовок);
    
    ОткрытьФорму(
        "Справочник.Файлы.Форма.ФормаСпискаПрисоединенныхФайлов", 
        Параметры,
        ПараметрыВыполненияКоманды.Источник, 
        ПараметрыВыполненияКоманды.Уникальность, 
        ПараметрыВыполненияКоманды.Окно);
        
КонецПроцедуры

все равно не выводит....добавил поля в справочник Файл, и вывел в форму "ФормаСпискаПрисоединенныхФайлов" этого справочника.

Ставлю точку остановки в общей команде, туда не заходит...откуда же она открывается и где тогда она?


И так, общая команда называется "ПрисоединенныеФайлыКОбъекту" открывает общую форму "ПрисоединенныеФайлы".

#Область ОбработчикиСобытий

&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
    
    ПараметрыФормы = Новый Структура;
    ПараметрыФормы.Вставить("ВладелецФайла",  ПараметрКоманды);
    ПараметрыФормы.Вставить("ТолькоПросмотр", ПараметрыВыполненияКоманды.Источник.ТолькоПросмотр);
    
    ОткрытьФорму("ОбщаяФорма.ПрисоединенныеФайлы",
                 ПараметрыФормы,
                 ПараметрыВыполненияКоманды.Источник,
                 ПараметрыВыполненияКоманды.Уникальность,
                 ПараметрыВыполненияКоманды.Окно);
    
КонецПроцедуры

#КонецОбласти

Попробуйте в предприятие перечитать стандартные настройки формы.
Такое бывает, когда динамическая форма была сформирована в одном варианте, открыта в предприятии, чуток изменена, потом, в конфигураторе добавляются колонки ( динамического списка )
без включённой галочки "Использовать всегда".
Выходы :
1. Перечитать стандартные настройки формы в предприятии
2. Поставить галочку "Использовать всегда" в конфигураторе.

Не помогает (

Вот что в конфигураторе:



В предприятии все равно не добавляется...

а там настройки видимости или еще чего?

или как вариант, таки не та форма..... если что, можно попробовать определить путем вывода сообщения пользователю.....

в коде нашел что когда эта форма открывается ей устанавливается динамический список. Сейчас попробую там поменять.

всмысле?

у общей формы "ПрисоединенныеФайлы" есть процедура:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
    
    УстановитьУсловноеОформление();
    
    Если Параметры.Свойство("АвтоТест") Тогда // Возврат при получении формы для анализа.
        Возврат;
    КонецЕсли;
    
    Если Параметры.ВладелецФайла = Неопределено Тогда
        ВызватьИсключение НСтр("ru = 'Список присоединенных файлов можно посмотреть
                                     |только в форме объекта-владельца.'");
    КонецЕсли;
    
    Если Параметры.РежимВыбора Тогда
        СтандартныеПодсистемыСервер.УстановитьКлючНазначенияФормы(ЭтотОбъект, "ВыборПодбор");
        РежимОткрытияОкна = РежимОткрытияОкнаФормы.БлокироватьОкноВладельца;
        
        Заголовок = НСтр("ru = 'Выбор присоединенного файла'");
        
        // Отбор не помеченных на удаление.
        ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбораДинамическогоСписка(
            Список, "ПометкаУдаления", Ложь, , , Истина,
            РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Обычный);
    Иначе
        Элементы.Список.РежимВыбора = Ложь;
    КонецЕсли;
    
    ИмяСправочникаХранилищаФайлов = Неопределено;
    НастроитьДинамическийСписок(ИмяСправочникаХранилищаФайлов);
    
    ТипСправочникаСФайлами = Тип("СправочникСсылка." + ИмяСправочникаХранилищаФайлов);
    
    МетаданныеСправочникаСФайлами = Метаданные.НайтиПоТипу(ТипСправочникаСФайлами);
    
    Если НЕ ПравоДоступа("ИнтерактивноеДобавление", МетаданныеСправочникаСФайлами) Тогда
        СкрытьКнопкиДобавления();
    Иначе
        Если ОбщегоНазначенияКлиентСервер.ЭтоВебКлиент() Тогда
            Если НЕ ПравоДобавления(ИмяСправочникаХранилищаФайлов, Параметры.ВладелецФайла) Тогда
                СкрытьКнопкиДобавления();
            КонецЕсли;
        КонецЕсли;
    КонецЕсли;
        
    Если НЕ ПравоДоступа("Редактирование", МетаданныеСправочникаСФайлами)
     ИЛИ НЕ ПравоДоступа("Редактирование", Параметры.ВладелецФайла.Метаданные())
     ИЛИ Параметры.ТолькоПросмотр = Истина Тогда
        
        СкрытьКнопкиИзменения();
    КонецЕсли;
    
    ИменаВсехКомандФормы = ПолучитьИменаКомандФормы();
    ИменаЭлементов = Новый Массив;
    
    Для Каждого ЭлементФормы Из Элементы Цикл
        
        Если ТипЗнч(ЭлементФормы) <> Тип("КнопкаФормы") Тогда
            Продолжить;
        КонецЕсли;
        
        Если ИменаВсехКомандФормы.Найти(ЭлементФормы.ИмяКоманды) <> Неопределено Тогда
            ИменаЭлементов.Добавить(ЭлементФормы.Имя);
        КонецЕсли;
    КонецЦикла;
    
    ИменаЭлементовКнопокФормы = Новый ФиксированныйМассив(ИменаЭлементов);
    
    ПриИзмененияИспользованияПодписанияИлиШифрованияНаСервере();
    
    Если ТекущийВариантИнтерфейсаКлиентскогоПриложения() = ВариантИнтерфейсаКлиентскогоПриложения.Версия8_2 Тогда
        Элементы.ФормаИзменить.Видимость = Ложь;
        Элементы.ФормаИзменить82.Видимость = Истина;
        Элементы.ФормаСкопировать.ТолькоВоВсехДействиях = Ложь;
        Элементы.ФормаУстановитьПометкуУдаления.ТолькоВоВсехДействиях = Ложь;
    КонецЕсли;
    
КонецПроцедуры

Вызывает процедуру НастроитьДинамическийСписок, вот в ней скорее всего и перестраивается Динамический список.

&НаСервере
Процедура НастроитьДинамическийСписок(ИмяСправочникаХранилищаФайлов)
    
    ТекстЗапроса = 
    "ВЫБРАТЬ
    |    Файлы.Ссылка КАК Ссылка,
    |    Файлы.ПометкаУдаления,
    |    ВЫБОР
    |        КОГДА Файлы.ПометкаУдаления = ИСТИНА
    |            ТОГДА Файлы.ИндексКартинки + 1
    |        ИНАЧЕ Файлы.ИндексКартинки
    |    КОНЕЦ КАК ИндексКартинки,
    |    Файлы.Наименование КАК Наименование,
    |    ВЫРАЗИТЬ(Файлы.Описание КАК СТРОКА(500)) КАК Описание,
    |    Файлы.Автор,
    |    Файлы.ДатаСоздания,
    |    Файлы.Изменил КАК Отредактировал,
    |    ДОБАВИТЬКДАТЕ(Файлы.ДатаМодификацииУниверсальная, СЕКУНДА, &СекундДоМестногоВремени) КАК ДатаИзменения,
    |    ВЫРАЗИТЬ(Файлы.Размер / 1024 КАК ЧИСЛО(10, 0)) КАК Размер,
    |    Файлы.ПодписанЭП,
    |    Файлы.Зашифрован,
    |    ВЫБОР
    |        КОГДА Файлы.ПодписанЭП
    |                И Файлы.Зашифрован
    |            ТОГДА 2
    |        КОГДА Файлы.Зашифрован
    |            ТОГДА 1
    |        КОГДА Файлы.ПодписанЭП
    |            ТОГДА 0
    |        ИНАЧЕ -1
    |    КОНЕЦ КАК НомерКартинкиПодписанЗашифрован,
    |    ВЫБОР
    |        КОГДА НЕ Файлы.Редактирует В (&ПустыеПользователи)
    |            ТОГДА ИСТИНА
    |        ИНАЧЕ ЛОЖЬ
    |    КОНЕЦ КАК ФайлРедактируется,
    |    ВЫБОР
    |        КОГДА Файлы.Редактирует = &ТекущийПользователь
    |            ТОГДА ИСТИНА
    |        ИНАЧЕ ЛОЖЬ
    |    КОНЕЦ КАК ФайлРедактируетТекущийПользователь,
    |    ВЫБОР
    |        КОГДА НЕ Файлы.Редактирует В (&ПустыеПользователи)
    |                И Файлы.Редактирует <> &ТекущийПользователь
    |            ТОГДА ИСТИНА
    |        ИНАЧЕ ЛОЖЬ
    |    КОНЕЦ КАК ФайлРедактируетДругойПользователь,
    |    Файлы.Редактирует КАК Редактирует
    |ИЗ
    |    &ИмяСправочника КАК Файлы
    |ГДЕ
    |    Файлы.ВладелецФайла = &ВладелецФайлов";
    
    ЗаголовокОшибки = НСтр("ru = 'Ошибка при настройке динамического списка присоединенных файлов.'");
    ОкончаниеОшибки = НСтр("ru = 'В этом случае настройка динамического списка невозможна.'");
    
    ИмяСправочникаХранилищаФайлов = ПрисоединенныеФайлыСлужебный.ИмяСправочникаХраненияФайлов(
        Параметры.ВладелецФайла, "", ЗаголовокОшибки, ОкончаниеОшибки);
    
    ПолноеИмяСправочника = "Справочник." + ИмяСправочникаХранилищаФайлов;
    Список.ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "&ИмяСправочника", ПолноеИмяСправочника);
    
    ПустыеПользователи = Новый Массив;
    ПустыеПользователи.Добавить(Неопределено);
    ПустыеПользователи.Добавить(Справочники.Пользователи.ПустаяСсылка());
    ПустыеПользователи.Добавить(Справочники.ВнешниеПользователи.ПустаяСсылка());
    
    Список.Параметры.УстановитьЗначениеПараметра("ВладелецФайлов",      Параметры.ВладелецФайла);
    Список.Параметры.УстановитьЗначениеПараметра("ТекущийПользователь", Пользователи.АвторизованныйПользователь());
    Список.Параметры.УстановитьЗначениеПараметра("ПустыеПользователи",  ПустыеПользователи);
    Список.Параметры.УстановитьЗначениеПараметра("СекундДоМестногоВремени", '00010101'); // Установка на клиенте
    Список.ОсновнаяТаблица = ПолноеИмяСправочника;
    Список.ДинамическоеСчитываниеДанных = Истина;
    
КонецПроцедуры

ВЕРНО?

А, ну тогда ясно, оно сует в список свой запрос. Копать туда надо, для своих изменений....

где-то еще по коду, формирование формы (участка списка в наше случае) там добавить вывод соответствующих колонок....

Получилось!
Вот код:

&НаСервере
Процедура НастроитьДинамическийСписок(ИмяСправочникаХранилищаФайлов)
    
    ТекстЗапроса = 
    "ВЫБРАТЬ
    |    Файлы.Ссылка КАК Ссылка,
    |    Файлы.ПометкаУдаления,
    |    ВЫБОР
    |        КОГДА Файлы.ПометкаУдаления = ИСТИНА
    |            ТОГДА Файлы.ИндексКартинки + 1
    |        ИНАЧЕ Файлы.ИндексКартинки
    |    КОНЕЦ КАК ИндексКартинки,
    |    Файлы.Наименование КАК Наименование,
    |    ВЫРАЗИТЬ(Файлы.Описание КАК СТРОКА(500)) КАК Описание,
    |    Файлы.Автор,
    |    Файлы.ДатаСоздания,
    |    Файлы.Изменил КАК Отредактировал,
    |    ДОБАВИТЬКДАТЕ(Файлы.ДатаМодификацииУниверсальная, СЕКУНДА, &СекундДоМестногоВремени) КАК ДатаИзменения,
    |    ВЫРАЗИТЬ(Файлы.Размер / 1024 КАК ЧИСЛО(10, 0)) КАК Размер,
    |    Файлы.ПодписанЭП,
    |    Файлы.Зашифрован,
    |    ВЫБОР
    |        КОГДА Файлы.ПодписанЭП
    |                И Файлы.Зашифрован
    |            ТОГДА 2
    |        КОГДА Файлы.Зашифрован
    |            ТОГДА 1
    |        КОГДА Файлы.ПодписанЭП
    |            ТОГДА 0
    |        ИНАЧЕ -1
    |    КОНЕЦ КАК НомерКартинкиПодписанЗашифрован,
    |    ВЫБОР
    |        КОГДА НЕ Файлы.Редактирует В (&ПустыеПользователи)
    |            ТОГДА ИСТИНА
    |        ИНАЧЕ ЛОЖЬ
    |    КОНЕЦ КАК ФайлРедактируется,
    |    ВЫБОР
    |        КОГДА Файлы.Редактирует = &ТекущийПользователь
    |            ТОГДА ИСТИНА
    |        ИНАЧЕ ЛОЖЬ
    |    КОНЕЦ КАК ФайлРедактируетТекущийПользователь,
    |    ВЫБОР
    |        КОГДА НЕ Файлы.Редактирует В (&ПустыеПользователи)
    |                И Файлы.Редактирует <> &ТекущийПользователь
    |            ТОГДА ИСТИНА
    |        ИНАЧЕ ЛОЖЬ
    |    КОНЕЦ КАК ФайлРедактируетДругойПользователь,
    |    Файлы.Редактирует КАК Редактирует,
    |    Файлы1.А1,
    |    Файлы1.А2,
    |    Файлы1.А3,
    |    Файлы1.А4
    |ИЗ
    |    &ИмяСправочника КАК Файлы
    |        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Файлы КАК Файлы1
    |        ПО Файлы.ВладелецФайла = Файлы1.ВладелецФайла
    |            И Файлы.Ссылка = Файлы1.Ссылка
    |ГДЕ
    |    Файлы.ВладелецФайла = &ВладелецФайлов";
    
    ЗаголовокОшибки = НСтр("ru = 'Ошибка при настройке динамического списка присоединенных файлов.'");
    ОкончаниеОшибки = НСтр("ru = 'В этом случае настройка динамического списка невозможна.'");
    
    ИмяСправочникаХранилищаФайлов = ПрисоединенныеФайлыСлужебный.ИмяСправочникаХраненияФайлов(
        Параметры.ВладелецФайла, "", ЗаголовокОшибки, ОкончаниеОшибки);
    
    ПолноеИмяСправочника = "Справочник." + ИмяСправочникаХранилищаФайлов;
    Список.ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "&ИмяСправочника", ПолноеИмяСправочника);
    
    ПустыеПользователи = Новый Массив;
    ПустыеПользователи.Добавить(Неопределено);
    ПустыеПользователи.Добавить(Справочники.Пользователи.ПустаяСсылка());
    ПустыеПользователи.Добавить(Справочники.ВнешниеПользователи.ПустаяСсылка());
    
    Список.Параметры.УстановитьЗначениеПараметра("ВладелецФайлов",      Параметры.ВладелецФайла);
    Список.Параметры.УстановитьЗначениеПараметра("ТекущийПользователь", Пользователи.АвторизованныйПользователь());
    Список.Параметры.УстановитьЗначениеПараметра("ПустыеПользователи",  ПустыеПользователи);
    Список.Параметры.УстановитьЗначениеПараметра("СекундДоМестногоВремени", '00010101'); // Установка на клиенте
    Список.ОсновнаяТаблица = ПолноеИмяСправочника;
    Список.ДинамическоеСчитываниеДанных = Истина;
    
КонецПроцедуры

Вот результат:

А как можно в этой форме сделать так, чтобы можно было клацать по этим флажкам, типо выбрано или нет (Истина/Ложь)? В динамическом списке такого по моему не сделать...Что посоветуете?

гемор тот еще.....

и все же))

ПриАктивизацииПоля......
вычислить что за поле, ссылку на элемент....
Оповестить.... с передчачей параметров вычисленных ранее
....
ОбработкаОповещения
код по изменению.....
....
PROFIT...

как-то так...

и да, новую тему.... вопрос новый...

окей. Попробую, спасибо!

и нам по шапке надают...

и запомнить следующее в ПриАктивизацииПоля() никаких (!!!) серверных вызовов,
собственно из-за этого такой гемор....