Всем добрый время!
Подкиньте советов, подскажите где копать..
Не судите строго, еще маладой в этом деле

Есть Регистр Накопления "БлокировкаТовара" С Измерением номенклатура и ресурсом количество
Задача состоит в том что бы пользователь мог блокировать товар в расходной накладной, который введен в табличную часть, кнопочкой на форме.

Собсна, создал я экспортную процедуру в модуле документа Расходная:

Процедура БлокировкаТовара()Экспорт
    Записать();
    Движения.БлокировкаТовара.Очистить();
    Запрос=Новый Запрос;
    Запрос.Текст=
    "ВЫБРАТЬ
    |    РасходнаяНакладнаяПереченьТоваров.Номенклатура,
    |    РасходнаяНакладнаяПереченьТоваров.Количество
    |ИЗ
    |    Документ.РасходнаяНакладная.ПереченьТоваров КАК РасходнаяНакладнаяПереченьТоваров
    |ГДЕ
    |    РасходнаяНакладнаяПереченьТоваров.Ссылка = &Ссылка";
    Запрос.УстановитьПараметр("Ссылка",Ссылка);
    Результат=Запрос.Выполнить().Выбрать();
    ТЗ=Запрос.Выполнить().Выгрузить();
    Пока Результат.Следующий() Цикл
    НаборЗаписей=РегистрыНакопления.БлокировкаТовара.СоздатьНаборЗаписей();
    Движение=НаборЗаписей.ДобавитьПриход();
    НаборЗаписей.Отбор.Регистратор.Установить(Ссылка);
    Движение.Номенклатура=Результат.Номенклатура;
    Движение.Период=Дата;
    Движение.Количество=Результат.Количество;
    КонецЦикла;
    Движения.БлокировкаТовара.Записать();
    НаборЗаписей.Записать();
КонецПроцедуры

И потом вызываю ее в обработчике этой кнопки:

&НаКлиенте
Процедура Заблокировать(Команда)
    ЗаблокироватьНаСервере();
КонецПроцедуры

&НаСервере
Процедура ЗаблокироватьНаСервере()
    Документ=РеквизитФормыВЗначение("Объект");
    Документ.БлокировкаТовара();
    ЗначениеВРеквизитФормы(Документ,"Объект");
КонецПроцедуры

В результате проблема следующая: В регистр записывается только 1 строчка с товаром из ТЧ..
Мне кажется косяк в процедуре модуля формы в преобразовании объекта, впервые сталкиваюсь с данным методом

Шо ж Вы набор записей в каждом проходе цикла создаёте?
Создайте процедуру обработки проведения конструктором и посмотрите як люды делають

Процедура БлокировкаТовара()Экспорт
    Записать();
    Движения.БлокировкаТовара.Очистить();
    Запрос=Новый Запрос;
    Запрос.Текст=
    "ВЫБРАТЬ
    |    РасходнаяНакладнаяПереченьТоваров.Номенклатура,
    |    РасходнаяНакладнаяПереченьТоваров.Количество
    |ИЗ
    |    Документ.РасходнаяНакладная.ПереченьТоваров КАК РасходнаяНакладнаяПереченьТоваров
    |ГДЕ
    |    РасходнаяНакладнаяПереченьТоваров.Ссылка = &Ссылка";
    Запрос.УстановитьПараметр("Ссылка",Ссылка);
    Результат=Запрос.Выполнить().Выбрать();
    НаборЗаписей=Движения.БлокировкаТовара;
    Пока Результат.Следующий() Цикл
       Движение=НаборЗаписей.ДобавитьПриход();
       Движение.Номенклатура=Результат.Номенклатура;
       Движение.Период=Дата;
       Движение.Количество=Результат.Количество;
    КонецЦикла;
    Движения.БлокировкаТовара.Записать();
КонецПроцедуры

Процедура БлокировкаТовара()Экспорт
    Записать();
    Движения.БлокировкаТовара.Очистить();
    Запрос=Новый Запрос;
    Запрос.Текст=
    "ВЫБРАТЬ
    |    РасходнаяНакладнаяПереченьТоваров.Ссылка КАК Регистратор,
    |    РасходнаяНакладнаяПереченьТоваров.Ссылка.Дата КАК Период,
    |    ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход) КАК ВидДвижения,
    |    РасходнаяНакладнаяПереченьТоваров.Номенклатура,
    |    РасходнаяНакладнаяПереченьТоваров.Количество
    |ИЗ
    |    Документ.РасходнаяНакладная.ПереченьТоваров КАК РасходнаяНакладнаяПереченьТоваров
    |ГДЕ
    |    РасходнаяНакладнаяПереченьТоваров.Ссылка = &Ссылка";
    Запрос.УстановитьПараметр("Ссылка",Ссылка);
    Результат=Запрос.Выполнить().Выгрузить();
    Движения.БлокировкаТовара.Загрузить(Результат);
    Движения.БлокировкаТовара.Записать();
КонецПроцедуры

Спасибо вам. Я что-то и не подумал насчет того что создается набор записей в каждом проходе цикла. Первый раз делаю набор записей вне модуля "обработка проведения"

Запись движений в процедуре проведения и вне ее, как правило не отличается. Для управляемого приложения так же есть стандарты формирования движений, используя модуль менеджера объекта, ДополнительнчеСвойства объекта, и общие процедуры по записи движений.

Они где-то описаны?

Без понятия, но на их наличие указывает использование одинакового механизма заполнения движения в разных конфигурация, в т.ч. у разных разработчиков (имеются ввиду продукты 1С:Совместимо)

меня ето смущает, в Таблице значений метод "Следующий()" не доступный. естественно цыкл не будет выполнятса.

ТЗ=Запрос.Выполнить().Выбрать();

ТЗ=Запрос.Выполнить().Выбрать();

Да эту строчку можно было бы убрать, я использовал ее что бы посмотреть лишь результат запроса

Движения.БлокировкаТовара.Загрузить(Результат);
Движения.БлокировкаТовара.Записать();

это какой то гламур