Платформа 8.2.16.368
"Управление торговым предприятием для Украины", редакция 1.2.
Разработка конфигурации: "ABBYY Ukraine", 2007-2011 (1.2.8.7)

Добрый день. Есть задача: "Установить "ЕдиницаПоКлассификатору", "Наименование" (единицы), и "Коэффициент" для каждого элемента в справочнике "Номенклатура"! Трудность у меня возникает в том, не знаю каким образом добавить строку с этими данными в элемент спр. "Номенклатура" на закладку "Единицы", откуда и будет браться информация для установки значения "ЕдиницаХраненияОстатков".
Если пишу так:

Спр = Справочники.Номенклатура; 
СпрЕд = Справочники.ЕдиницыИзмерения;
СпрКлас = Справочники.КлассификаторЕдиницИзмерения;
    
ЕдинИзм = СпрЕд.НайтиПоКоду(001); 
СпрКлас = СпрЕд.НайтиПоКоду(001); 

Выборка = Спр.Выбрать();
Пока выборка.Следующий() = 1 Цикл
        Если ЗначениеЗаполнено(выборка.ЕдиницаХраненияОстатков) Тогда
            Продолжить;
        Иначе
            выборка.ЕдиницаХраненияОстатков = ЕдинИзм.Ссылка; 
            выборка.ЕдиницаХраненияОстатков.ЕдиницаПоКлассификатору = СпрКлас.Ссылка;
            выборка.ЕдиницаХраненияОстатков.Коэффициент = "1";
            выборка.ЕдиницаХраненияОстатков.Наименование = "шт";
            Выборка.ЕдиницаДляОтчетов = ЕдинИзм.Ссылка;
            Выборка.ИзмеряетсяТолькоВСуммовомВыражении = Истина;
            Выборка.СтавкаНДС = Перечисления.СтавкиНДС.НДС20;
            Если Выборка.СтатьяЗатрат.Пустая() Тогда
                Выборка.СтатьяЗатрат = Справочники.СтатьиЗатрат.НайтиПоКоду("100000003");
            КонецЕсли;
            Выборка.УровеньВВыборке()
        КонецЕсли; 
КонецЦикла;

Получпю ОШИБКУ : "ЕдиницаХраненияОстатков" Не доступна для записи!
Подскажите, как возможно учтановить "Выборка.ЕдиницаХраненияОстатков"?

Неудачная попытка приспособить семерошный код к восьмерке...

upd: проявлю доброту, подскажу надеюсь и вы все таки, проявите взаимность, ознакомитесь с правилами форума.

Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
               |    Номенклатура.Ссылка
               |ИЗ
               |    Справочник.Номенклатура КАК Номенклатура
               |ГДЕ
               |    Номенклатура.ЕдиницаХраненияОстатков = ЗНАЧЕНИЕ(Справочник.ЕдиницыИзмерения.ПустаяСсылка)";
               
Выборка = Запрос.Выполнить().Выбрать();

Пока Выборка.Следующий() Цикл
    СпрОбъект = Выборка.Ссылка.ПолучитьОбъект();
    СпрЕдИзм = Справочники.ЕдиницыИзмерения.НайтиПоКоду(001,,,Выборка.Ссылка);
    Если СпрЕдИзм = Неопределено Тогда
        СпрЕдИзм = Справочники.ЕдиницыИзмерения.СоздатьЭлемент();
        СпрЕдИзм.ЕдиницаПоКлассификатору = Справочники.КлассификаторЕдиницИзмерения.НайтиПоКоду(001);
        СпрЕдИзм.Владелец = Выборка.Ссылка;
        СпрЕдИзм.Наименование = "шт";
        СпрЕдИзм.Коэффициент = 1;
        Попытка
            СпрЕдИзм.Записать();
        Исключение
            Сообщить(ОписаниеОшибки());
            Продолжить;
        КонецПопытки;
    КонецЕсли;
    
    СпрОбъект.ЕдиницаХраненияОстатков = СпрЕдИзм.Ссылка;
    СпрОбъект.ЕдиницаДляОтчетов = СпрЕдИзм.Ссылка;
    СпрОбъект.ИзмеряетсяТолькоВСуммовомВыражении = Истина;
    СпрОбъект.СтавкаНДС = Перечисления.СтавкиНДС.НДС20;
    
    Если Не ЗначениеЗаполнено(СпрОбъект.СтатьяЗатрат) Тогда
        СпрОбъект.СтатьяЗатрат = Справочники.СтатьиЗатрат.НайтиПоКоду("100000003");
    КонецЕсли;
    Попытка
        СпрОбъект.Записать();
    Исключение
        Сообщить(ОписаниеОшибки());
    КонецПопытки;    
КонецЦикла;

Извините за нарушения. Чес слово, не хотел. Спасибо за помощь!

Только начинаю учить 8-ку, потому много 7-шного "жаргона" )