В данной статье рассмотрено предложение ИЗ, его место и роль в языке запросов 1С:Предприятия 8.
Предложение ИЗ присутствует почти в каждом запросе 1С:Предприятия 8, так как в большинстве случаев именно в нем указываются таблицы-источники данных для запроса. Кроме того, предложение ИЗ позволяет выполнить соединение нескольких таблиц, а также указать параметры при получении виртуальной таблицы.
Ниже рассмотрены следующие темы:
- Место предложения ИЗ в структуре запроса
- Таблицы-источники
- Примеры запросов с предложением ИЗ:
- Выборка данных из различных таблиц-источников
- Виртуальные таблицы
- Псевдонимы источников
- Вложенный запрос как источник
- Соединение таблиц
- Место предложения ИЗ в структуре запроса
Место предложения ИЗ в структуре запроса
- В запросе может не быть предложения ИЗ (если поля в списке выборки полностью квалифицированы, т.е. включают имя таблицы).
- Источников в запросе может быть несколько (в этом случае, они обычно соединяются по определенному условию)
- В качестве источника может быть обычная таблица-источник, виртуальная таблица с параметрами, а также вложенный запрос
- Для источника можно назначить псевдоним с помощью ключевого слова КАК (Внимание: если источником является вложенный запрос, то псевдоним обязателен).
Таблицы-источники
Все таблицы-источники можно поделить на три класса:
- Таблицы, связанные со ссылочными объектами конфигурации (справочники, планы, документы и журналы документов)
- Таблицы, связанные с регистрами (сведений, накопления, бухгалтерии, расчета)
- Таблицы, связанные с остальными объектами конфигурации (константы, последовательности, критерии отбора)
Примеры запросов с предложением ИЗ
Выборка данных из различных таблиц-источников
Выборка элементов справочника:
ВЫБРАТЬ *, Представление ИЗ Справочник.Номенклатура
ВЫБРАТЬ Ссылка, Номер, Дата, Представление
ИЗ Документ.АвансовыйОтчет
ВЫБРАТЬ Ссылка, Номер, Дата
ИЗ ЖурналДокументов.СкладскиеДокументы
ГДЕ Проведен = Истина
ВЫБРАТЬ Номенклатура, ПодразделениеКомпании, СуммаПродажи
ИЗ РегистрНакопления.ПродажиКомпании
ГДЕ Активность = Истина
//обращение к табличной части документа
ВЫБРАТЬ Номенклатура, Количество
ИЗ Документ.АвансовыйОтчет.Товары
ВЫБРАТЬ Ссылка.Номер, Ссылка.Дата, Номенклатура, Количество
ИЗ Документ.АвансовыйОтчет.Товары
//обращение к виртуальной таблице регистра накопления (вызов без параметров)
ВЫБРАТЬ * ИЗ РегистрНакопления.ПродажиКомпании.Обороты
//выборка оборотов за период
ВЫБРАТЬ * ИЗ РегистрНакопления.ПродажиКомпании.Обороты(&Нач, &Кон,,)
//выборка оборотов по конкретному товару
ВЫБРАТЬ * ИЗ РегистрНакопления.ПродажиКомпании.Обороты(,,,Номенклатура = &ВыбТовар)
//остатки товаров на определенную дату
ВЫБРАТЬ * ИЗ РегистрНакопления.ОстаткиТоваровКомпании.Остатки(&ВыбДата,)
ВЫБРАТЬ Продажи.Номенклатура,
Продажи.ПодразделениеКомпании,
Продажи.СуммаПродажи
ИЗ РегистрНакопления.ПродажиКомпании КАК Продажи
ГДЕ Активность = Истина
ВЫБРАТЬ
Товары.Номенклатура КАК Товар,
Товары.Номенклатура.Артикул
ИЗ
(
ВЫБРАТЬ Номенклатура ИЗ Документ.ВнутреннийЗаказ.Товары
ОБЪЕДИНИТЬ
ВЫБРАТЬ Номенклатура ИЗ Документ.ЗаказПокупателя.Товары
) КАК Товары
ВЫБРАТЬ Спр.Ссылка, ДокТовары.Номенклатура
ИЗ Справочник.Номенклатура КАК Спр, Документ.АвансовыйОтчет.Товары КАК ДокТовары
ВЫБРАТЬ ДокТовары.Номенклатура, Спр.Артикул, ДокТовары.Количество, ДокТовары.Сумма
ИЗ Справочник.Номенклатура КАК Спр
СОЕДИНЕНИЕ Документ.АвансовыйОтчет.Товары КАК ДокТовары
ПО Спр.Ссылка = ДокТовары.Номенклатура
Замечание. В данном примере того же эффекта можно добиться, если просто обращаться к имени поля через точку, что называется разыменованием ссылочных полей. При этом соединение таблиц производится неявно. Возможность разыменования полей в 1С:Предприятии 8 допускает обращение к свойствам объектов через несколько точек, например, «Номенклатура.Поставщик.Страна». Это позволяет значительно упростить написание запросов.Если в таблице будет найдено несколько записей, удовлетворяющих условию соединения, то в результат запроса будут включены все эти записи.
Правило. В случае левого внешнего соединения в результат запроса будут включены все записи из первого источника; они будут соединены с записями из второго источника при выполнении указанного условия. Строки результата запроса, для которых не найдено соответствующих условию записей из второго источника, будут содержать значение NULL в полях, формируемых на основании записей из этого источника.
ВЫБРАТЬ Спр.Наименование КАК Валюта, Рег.Курс
ИЗ Справочник.Валюты КАК Спр
ЛЕВОЕ ВНЕШНЕЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют.СрезПоследних КАК Рег
ПО Спр.Ссылка = Рег.Валюта
Правило. В случае правого внешнего соединения в результат запроса будут включены все записи из второго источника; они будут соединены с записями из первого источника при выполнении указанного условия. Строки результата запроса, для которых не найдено соответствующих условию записей из первого источника, будут содержать значение NULL в полях, формируемых на основании записей из этого источника.Правое внешнее соединение полностью аналогично левому, за исключением того, что таблицы поменялись местами. Например, представленный ниже запрос эквивалентен предыдущему, но вместо левого, используется правое внешнее соединение:
ВЫБРАТЬ Спр.Наименование КАК Валюта, Рег.Курс
ИЗ РегистрСведений.КурсыВалют.СрезПоследних() КАК Рег
ПРАВОЕ ВНЕШНЕЕ СОЕДИНЕНИЕ Справочник.Валюты КАК Спр
ПО Спр.Ссылка = Рег.Валюта
Правило. При полном внешнем соединении в результат запроса будут включены все записи из обоих источников; они будут соединены друг с другом при выполнении указанного условия. Строки результата запроса, для которых не найдено соответствующих условию записей из какого-либо источника, будут содержать NULL в полях, формируемых на основании записей из этого источника.
Украинский 1С форум: всё про 1С 8.3, 1С 8.2, 1С 8.1, 1С 8.0, 1С 7.7
https://pro1c.org.ua