Если движения документа могут создаваться или редактироваться не только при проведении, то нужно отработать изменение даты документа в процедуре ПередЗаписью в модуле документа:

Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)

	//определим, нужно ли обновлять дату в движениях
	ОбновлятьДату = ЭтоНовый() Или Движения.УчетНоменклатуры.Модифицированность();
	Если Не ОбновлятьДату Тогда

		// Проверка что изменилась дата
		Запрос = Новый Запрос;
		Запрос.УстановитьПараметр("ТекДок", Ссылка);
		Запрос.Текст = "ВЫБРАТЬ Дата ИЗ Документ.ОперацияПоУчетуНоменклатуры ГДЕ Ссылка = &ТекДок";
		Выборка = Запрос.Выполнить().Выбрать();
		Выборка.Следующий();
		ОбновлятьДату = Выборка.Дата <> Дата; 

	КонецЕсли; 

	//если нужно установим всем новую дату
	Если ОбновлятьДату Тогда

		Если Не Движения.УчетНоменклатуры.Выбран() И Не Движения.УчетНоменклатуры.Модифицированность() Тогда
		      Движения.УчетНоменклатуры.Прочитать(); 
		КонецЕсли; 

		Для Каждого Запись Из Движения.УчетНоменклатуры Цикл
		       Запись.Период = Дата;
		КонецЦикла; 

	КонецЕсли; 

КонецПроцедуры

где УчетНоменклатуры — имя регистра накопления, а ОперацияПоУчетуНоменклатуры — имя документа, в котором есть возможность редактировать набор записей по регистру УчетНоменклатуры.