Управляемые формы, конфигурация "УНФ". Реально ли передать в параметры открытия формы выбора документа условие: дата документа в некотором интервале.
Насколько мне известно, можно передать только точные значения...

ПараметрыОткрытияФормыВыбора=Новый Структура;
Пар = Новый Структура;
Пар.Вставить("Контрагент", Объект.Контрагент);
Пар.Вставить("Организация", Объект.Организация);
//сюда бы добавить период отбора документа. Например, документы за последние 2 месяца. Сейчас за все годы попадают в список, не годится так.
ПараметрыОткрытияФормыВыбора.Вставить("Отбор", Пар);    
ОписаниеОповещения = Новый ОписаниеОповещения("Тест", ЭтаФорма);  

ОткрытьФорму("Документ.ЗаказПоставщику.Форма.ФормаВыбора", ПараметрыОткрытияФормыВыбора,ЭтаФорма,,,,ОписаниеОповещения);

А два параметра не проходит ? 1- больше А, 2- меньше Б ???

Подозреваю, что нужно это сделать без изменения кода конфигурации.

Vofka
Да, так и есть. Нужно типовыми средствами как-то сделать. Но как период всунуть в "Дату", непонятно.

Inkognito @ Сегодня, 11:16 необходимо зарегистрироваться для просмотра ссылки ,
теоретически возможно
только придется вероятнее всего получить форму

Форма = Документы.ЗаказПоставщику.ПолучитьФормуВыбора();

а потом уже работать со Списком - Форма.Список.Отбор = Отбор компоновки данных

Там уже получать отборы и потом уже открывать непосредственно форму.

Форма.Открыть();

уважаемый, Упр. формы открываются по-другому (тем более с установкой отбора списка)




я в маразме ?

В управляемых формах тоже можно получить форму, что-то с ней поделать и потом открыть.


Не исключено.

вот такая фигня не проходит ? - самому впадло пробовать

Сп = Новый СписокЗначений;
Сп.Добавить(Значение1);
Сп.Добавить(Значение2);

ПараметрыОтбор = Новый Структура("Контрагент", Сп);
ПараметрыОткрытия = Новый Структура("Отбор", ПараметрыОтбор);
ОткрытьФорму("Документ.........Форма.ФормаВыбора", ПараметрыОткрытия, Элемент);

sava1
Доработав немного код выше:

Сп = Новый СписокЗначений;
Сп.Добавить(ДобавитьМесяц(НачалоДня(ТекущаяДата()), -2));
Сп.Добавить(КонецДня(ТекущаяДата()));
ПараметрыОтбор = Новый Структура("Дата", Сп);

Пустой список в результате получаем.
Также попробовал вместо "Дата" --- "Период": никаких изменений по сравнению с базовым кодом (т.е. список отображается полностью по всем годам)

Inkognito @ Сегодня, 16:21 необходимо зарегистрироваться для просмотра ссылки ,
Попробуйте так
Дата отбора = текущая дата минус 3 месяца, можете поставить свою.

    Форма = Документы.ЗаказПоставщику.ПолучитьФормуВыбора();
        
    Отбор = Форма.Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
    Отбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Дата");
    Отбор.ВидСравнения = ВидСравненияКомпоновкиДанных.БольшеИлиРавно;
    Отбор.Использование = Истина;
    Отбор.ПравоеЗначение =  ДобавитьМесяц(ТекущаяДата(),-3);
    
    Отбор = Форма.Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
    Отбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Контрагент");
    Отбор.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
    Отбор.Использование = Истина;
    Отбор.ПравоеЗначение =  Объект.Контрагент;

    Отбор = Форма.Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
    Отбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Организация");
    Отбор.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
    Отбор.Использование = Истина;
    Отбор.ПравоеЗначение =  Объект.Организация;
    
    Форма.Открыть();

fly @ Сегодня, 17:11 необходимо зарегистрироваться для просмотра ссылки ,
увы проставить интервал "Между" не получиться

типа сравнения между в СКД нет для левого соединения.
увы там или больше (больше или равно) или меньше (меньше или равно), или равно, или не равное, или в списке...... и т.д.
идею получать весь список дат и сравнивать("В списке" или "Не в списке"), думаю это не очень хорошая идея - хотя если очень и очень надо, то возможно и такое.

fly @ Today, 16:34 необходимо зарегистрироваться для просмотра ссылки ,
Почему же? Можно добавить два условия: с "больше или равно" и "меньше или равно".

Petre @ Сегодня, 17:36 необходимо зарегистрироваться для просмотра ссылки ,

может быть, теорию не настолько знаю, возможно пересечение отоборов
или
сработает...

тут надо пробовать



сработало,
да ок

я не прав

".....увы проставить интервал "Между" не получиться...."

Не рекомендуют - необходимо зарегистрироваться для просмотра ссылки

по-правильному - устанавливаем фикс. настройки и открываем форму - 2 параметра (большравно и меньшеравно) - о чем и писАл в #2

кстати - по ПолучитьФорму - необходимо зарегистрироваться для просмотра ссылки

Если вызывать процедуру на клиенте, ругается при сохранении на 1 строку:

Переменная не определена (Документы)

Если вызывать на сервере, ругается при выполнении серверной функции:

Форма = Документы.ЗаказПоставщику.ПолучитьФормуВыбора();
по причине:
Интерактивные операции недоступны

Где ее правильно вызвать (пример кода от fly)?

ФормуВыбора на сервере - вернуть на клиент - открыть

На клиенте.

Доступность:
Тонкий клиент, веб-клиент, мобильный клиент, толстый клиент, мобильное приложение(клиент).

а по-человечески - так

ФормаВыбора = ПолучитьФорму("Справочник.ТестСправочник.Форма.ФормаВыбора"

sava1
Работает прекрасно, спасибо. А как получить результат?

ОписаниеОповещения = Новый ОписаниеОповещения("Тест", ЭтаФорма);  
ОткрытьФорму("Документ.ЗаказПоставщику.Форма.ФормаВыбора", ПараметрыОткрытияФормыВыбора,ЭтаФорма,,,,ОписаниеОповещения);
//тут результат получаем в процедуре Тест()

//тут нет конструктора ОписаниеОповещения
Форма = ПолучитьФорму("Документ.ЗаказПоставщику.Форма.ФормаВыбора");

Inkognito @ Today, 10:49 необходимо зарегистрироваться для просмотра ссылки ,
Так используйте ОткрытьФорму.

Всем спасибо, заработало!
необходимо зарегистрироваться для просмотра ссылки

&НаКлиенте
Процедура ВыборДокумента(Команда)
                    
        ОписаниеОповещения = Новый ОписаниеОповещения("ПолучитьЗначениеВыбора", ЭтаФорма);  
        Форма = ОткрытьФорму("Документ.ЗаказПоставщику.Форма.ФормаВыбора",,ЭтаФорма,,,,ОписаниеОповещения);
    
        Отбор = Форма.Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
        Отбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Дата");
        Отбор.ВидСравнения = ВидСравненияКомпоновкиДанных.БольшеИлиРавно;
        Отбор.Использование = Истина;
        Отбор.ПравоеЗначение =  ДобавитьМесяц(ТекущаяДата(),-3);
        
        Отбор = Форма.Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
        Отбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Дата");
        Отбор.ВидСравнения = ВидСравненияКомпоновкиДанных.МеньшеИлиРавно;
        Отбор.Использование = Истина;
        Отбор.ПравоеЗначение = ТекущаяДата();
        
        Отбор = Форма.Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
        Отбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Контрагент");
        Отбор.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
        Отбор.Использование = Истина;
        Отбор.ПравоеЗначение =  Объект.Контрагент;
        
        Отбор = Форма.Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
        Отбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Организация");
        Отбор.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
        Отбор.Использование = Истина;
        Отбор.ПравоеЗначение =  Объект.Организация;
        
        Форма.Открыть();
        
КонецПроцедуры

&НаКлиенте
Процедура ПолучитьЗначениеВыбора(Результат, ДополнительныеПараметры) Экспорт
    
     Рез = Результат;

КонецПроцедуры

Форма.Открыть(); в конце, наверное, лишнее.

а вот так ?

&НаКлиенте
Процедура ОткрытьФормуА(Команда)
    
    фиксНастройки = Новый НастройкиКомпоновкиДанных;
    
    эОтбор = фиксНастройки.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
    эОтбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Дата");
    эОтбор.ВидСравнения = ВидСравненияКомпоновкиДанных.БольшеИлиРавно;
    эОтбор.ПравоеЗначение = Объект.Период.ДатаНачала;
    эОтбор.Использование = Истина;
    
    эОтбор = фиксНастройки.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
    эОтбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Дата");
    эОтбор.ВидСравнения = ВидСравненияКомпоновкиДанных.МеньшеИлиРавно;
    эОтбор.ПравоеЗначение = Объект.Период.ДатаОкончания;
    эОтбор.Использование = Истина;
 
    эОтбор.РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Недоступный;
 
    ПараметрыФормы = Новый Структура;
    ПараметрыФормы.Вставить("ФиксированныеНастройки", фиксНастройки);

    ОткрытьФорму("Документ.РеализацияТоваровУслуг.Форма.ФормаСписка", ПараметрыФормы, ЭтаФорма);
КонецПроцедуры