"Управление торговым предприятием для Украины", редакция 1.2. (1.2.45.2)

Добрый день. Помогите с такой проблемой. При формировании Платежного поручения в Номере поручения автоматически выбивается какой то старый номер и всегда один и тот же. После чего это произошло - неизвестно. Ставим правильные номера вручную. Но когда платежек по 30 шт. - напрягает руками изменять (( Подскажите как исправить эту проблему?

admin@stark.ua @ Сегодня, 14:23 необходимо зарегистрироваться для просмотра ссылки ,
В Бухгалтерии для Украины есть соответствующий регистр (Нумерация), попробуйте и в УТП поискать.

Нумерация платежек ежегодно начинается с единицы для каждого расчетного счета. В окне платежных документов выбираем период 2018 года. В окошко поиска вбиваем номер на единицу меньше "старого номера". Таким образом находим ошибочный номер и изменяем его.

vita2011 @ Вчера, 22:58 необходимо зарегистрироваться для просмотра ссылки ,
Проблема не в номере документа, а номере поручения (( Номер я знаю как исправить.

Так ведь и имелся ввиду.


vita2011 @ Сегодня, 21:54 необходимо зарегистрироваться для просмотра ссылки ,
выбивается какой то старый номер и всегда один и тот же - это номер 5641 ? И его нужно исправить на 5777 ?

vita2011 @ Вчера, 21:59 необходимо зарегистрироваться для просмотра ссылки ,
Такого документа уже нет (((

admin@stark.ua @ Сегодня, 8:55 необходимо зарегистрироваться для просмотра ссылки ,

В модуле документа есть код - курите:

Процедура УстановитьНомерПоручения()
    
    Если глЗначениеПеременной("ИспользоватьУправляемыеБлокировки") Тогда
        СтруктураПараметровБлокировка = Новый Структура("ТипТаблицы, ИмяТаблицы", "Справочник", "БанковскиеСчета");
        
        ЗначенияБлокировки = Новый Структура;
        ЗначенияБлокировки.Вставить("Ссылка",      СчетОрганизации);
        ОбщегоНазначения.УстановитьУправляемуюБлокировку(СтруктураПараметровБлокировка, ЗначенияБлокировки, , Ложь, "");
    КонецЕсли;
    
    Запрос = Новый Запрос;
    Запрос.УстановитьПараметр("ДатаНачалаГода", НачалоГода(Дата));
    Запрос.УстановитьПараметр("ДатаКонцаГода", КонецГода(Дата));
    Запрос.УстановитьПараметр("Организация", Организация);
    Запрос.УстановитьПараметр("СчетОрганизации", СчетОрганизации);
    Запрос.УстановитьПараметр("Ссылка", Ссылка);

    Запрос.Текст =
    "ВЫБРАТЬ РАЗРЕШЕННЫЕ
    |    НомерПоручения КАК НомерПоручения
    |ИЗ
    |    Документ.ПлатежноеПоручениеИсходящее КАК ПлатежноеПоручение
    |
    |ГДЕ
    |    ПлатежноеПоручение.Организация = &Организация
    |    //самого себя не учитываем
    |    И ПлатежноеПоручение.Ссылка <> &Ссылка
    |    И ПлатежноеПоручение.СчетОрганизации = &СчетОрганизации
    |    И ПлатежноеПоручение.Дата >= &ДатаНачалаГода
    |    И ПлатежноеПоручение.Дата <= &ДатаКонцаГода";

    СписокПлатежек = Запрос.Выполнить().Выбрать();
    
    ТаблицаЗначений = Новый ТаблицаЗначений;
     
    ТаблицаЗначений.Колонки.Добавить("Номер"); 
    ТаблицаЗначений.Колонки.Добавить("Длина"); 

    Пока СписокПлатежек.Следующий() Цикл
        НоваяСтрока = ТаблицаЗначений.Добавить(); 
        НоваяСтрока.Номер = СписокПлатежек.НомерПоручения; 
        НоваяСтрока.Длина = СтрДлина(СписокПлатежек.НомерПоручения); 
    КонецЦикла;
    
    ТаблицаЗначений.Сортировать("Длина Убыв, Номер Убыв");
    
    Если ТаблицаЗначений.Количество() > 0 Тогда
        Попытка
            НомерПоручения = Формат(Число(ТаблицаЗначений[0].Номер) + 1, "ЧГ=0");
        Исключение
            НомерПоручения = 1;    
        КонецПопытки;
    Иначе
        НомерПоручения = 1;
    КонецЕсли;
    
КонецПроцедуры

awp @ 28.09.18, 9:26 необходимо зарегистрироваться для просмотра ссылки ,Разобрался. Может кому будет интересно. Бухгалтер изменила вручную номер поручения и к 4-х значному числу добавила точку в конце (2525.), а программа когда когда ищет последнюю платежку сортирует и по номеру платежного документа и по длине (количество знаков). Убрали точку, все заработало. Проблема решена. Спасибо.