Заказы на доработку 1С (сервис удаленной работы)

Хранилище

База знаний
Бесплатные отчеты, обработки, конфигурации, внешние компоненты для 1С Статьи, описание работы, методики по работе с 1С

Здравствуйте, гость ( Вход | Зарегистрироваться )



> Отчет по всем счетам и всем субконто развернуто          
awp Подменю пользователя
сообщение 18.09.12, 14:56
Сообщение #1

Почти ветеран
Иконка группы
Группа: Местный
Сообщений: 520
Спасибо сказали: 70 раз
Рейтинг: 51.3

Есть бухия 1С7 исписана в доль и поперек. Необходимо сформировать отчет по всем счетам(субсчетам) и субконто развернуто.

Примерно так
Счет Субконто1 Субконто2 Субконто3 Субконто4 СКД СКК СКД(,2) СКК(,2) Валюта

Подскажите куда копать. Спасибо!


Signature
Бухгалтер - это не профессия! Это диагноз!

Cthulhu Подменю пользователя
сообщение 18.09.12, 15:19
Сообщение #2

Завсегдатай
Иконка группы
Группа: Местный
Сообщений: 224
Из: не ту страну назвали Гондурасом
Спасибо сказали: 83 раз
Рейтинг: 0

а Типы Субконто для каждого счета - куда-с пихать? а НЕвалютные счета? а колонки для не-валютных сумм? а кол-во не нужно? а признак забалансового счета? а как со счетами-группами - не выводить вообще? а какое сальдо по оборотным субконто? (и как в резултате это всё в отчете выглядеть должно?)
А так - копать в сторону бух.итогов.
Для каждого встречаемого количества субконто - список счетов и отдельный бух.запрос по нему с "ИспользоватьСубконто" без параметров (счета очень желательно указывать в виде строки кодов а не СЗ - были там какие-то глюки). Собирать результаты макс.разворотов в ТЗ. Потом эту ТЗ сортануть и распечатать.
прим.: "по разному количеству субконто" - потому что в результат бух.запроса не попадают данные по счету, на котором количество субконто меньше количества методов ИспользоватьСубконто(), примененных в настройке бух.запроса - даже на обходах номера субконто, которій (номер субконто) есть на єтих счетах - есть такое не очевидное обстоятельство

awp Подменю пользователя
сообщение 18.09.12, 15:32
Сообщение #3

Почти ветеран
Иконка группы
Группа: Местный
Сообщений: 520
Спасибо сказали: 70 раз
Рейтинг: 51.3

Цитата(Cthulhu @ 18.09.12, 16:19) *
а Типы Субконто для каждого счета - куда-с пихать? а НЕвалютные счета? а колонки для не-валютных сумм? а кол-во не нужно? а признак забалансового счета? а как со счетами-группами - не выводить вообще? а какое сальдо по оборотным субконто? (и как в резултате это всё в отчете выглядеть должно?)
А так - копать в сторону бух.итогов.
Для каждого встречаемого количества субконто - список счетов и отдельный бух.запрос по нему с "ИспользоватьСубконто" без параметров (счета очень желательно указывать в виде строки кодов а не СЗ - были там какие-то глюки). Собирать результаты макс.разворотов в ТЗ. Потом эту ТЗ сортануть и распечатать.
прим.: "по разному количеству субконто" - потому что в результат бух.запроса не попадают данные по счету, на котором количество субконто меньше количества методов ИспользоватьСубконто(), примененных в настройке бух.запроса - даже на обходах номера субконто, которій (номер субконто) есть на єтих счетах - есть такое не очевидное обстоятельство


Вы внимательно читали? Может я както неинформативно описал?

Если чегото нет - значит нет! Если по счету нет субконто3 то значет его нет и там пусто.
Если нет валюты значит нет просто СКД если есть то к нему еще будет СКД(,2)

Идея с кучей Бух итогов както меня не радует sad.gif . Может есть другой вариант?



Signature
Бухгалтер - это не профессия! Это диагноз!

alex040269 Подменю пользователя
сообщение 18.09.12, 15:46
Сообщение #4

Крутой
Иконка группы
Группа: Местный
Сообщений: 1626
Из: Гуляйполе
Спасибо сказали: 236 раз
Рейтинг: 0

может это спасет?

Когда-то пришлось писать отчет под разные конфигурации. Количество субконто везде разные.
вот фрагмент кода:

                максСубконто = Ит.Счет.КоличествоСубконто();
        ИтСубк.ИспользоватьСубконто(ВидыСубконто.Контрагенты);
        ш = 1;
        Пока ш <= максСубконто Цикл
            Если Ит.Счет.ВидСубконто(ш) <> ВидыСубконто.Контрагенты Тогда
                ИтСубк.ИспользоватьСубконто(Ит.Счет.ВидСубконто(ш));
            КонецЕсли;
            ш = ш + 1;
        КонецЦикла;        
        ИтСубк.ВыполнитьЗапрос(Дата1-1,Дата1-1,Ит.Счет);
        Если ИтСубк.ВыбратьСубконто(1) = 0 Тогда
            Сообщить("Нет итогов субконто по счету "+ Строка(Ит.Счет));
            Продолжить;
        КонецЕсли;
        тек = 1;
        Пока тек > 0 Цикл
            Пока ИтСубк.ПолучитьСубконто(тек) = 1 Цикл
                Если тек = 1 Тогда
                    Если тз.НайтиЗначение(ИтСубк.Субконто(тек),,"Субконто") = 1 Тогда
                        тз.Дт = тз.Дт + ИтСубк.СКД();
                        тз.Кт = тз.Кт + ИтСубк.СКК();
                    Иначе
                        тз.НоваяСтрока();
                        тз.Субконто = ИтСубк.Субконто(тек);
                        тз.Счета = СоздатьОбъект("ТаблицаЗначений");
                        тз.Счета.НоваяКолонка("Счет","Счет");
                        тз.Счета.НоваяКолонка("Дт","Число",19,2);
                        тз.Счета.НоваяКолонка("Кт","Число",19,2);
                        тз.Дт = ИтСубк.СКД();
                        тз.Кт = ИтСубк.СКК();
                    КонецЕсли;
                КонецЕсли;
                Если тек < максСубконто Тогда
                    тек=тек+1;
                    Если ИтСубк.ВыбратьСубконто(тек) = 0 Тогда
                        Сообщить("Не выбран субконто уровня "+Строка(тек));
                    КонецЕсли;
                Иначе
                    ИтСубк.ВыбратьСчета();
                    Пока ИтСубк.ПолучитьСчет() = 1 Цикл
                        Если тз.Счета.НайтиЗначение(ИтСубк.Счет,,"Счет") = 1 Тогда
                            тз.Счета.Дт = тз.Счета.Дт + ИтСубк.СКД();
                            тз.Счета.Кт = тз.Счета.Кт + ИтСубк.СКК();
                        Иначе                            
                            тз.Счета.НоваяСтрока();
                            тз.Счета.Счет = ИтСубк.Счет;
                            тз.Счета.Дт = ИтСубк.СКД();
                            тз.Счета.Кт = ИтСубк.СКК();
                        КонецЕсли
                    КонецЦикла;
                КонецЕсли;
            КонецЦикла;
            тек = тек-1;
        КонецЦикла;
    КонецЦикла;





Signature
Никогда не бойся делать то, что не умеешь, помни - Ноев ковчег был построен любителем, профессионалы построили Титаник.
ЗиУП

Спасибо сказали: awp,

Cthulhu Подменю пользователя
сообщение 18.09.12, 15:48
Сообщение #5

Завсегдатай
Иконка группы
Группа: Местный
Сообщений: 224
Из: не ту страну назвали Гондурасом
Спасибо сказали: 83 раз
Рейтинг: 0

Цитата(awp @ 18.09.12, 15:32) *
Вы внимательно читали? Может я както неинформативно описал?

особенно слова " отчет по всем счетам(субсчетам) и субконто развернуто" и "примерно".
да, неинформативно. а потом и с излишними брызгами - что зря, можно было просто ответить на уточняющие вопросы.
конечно, есть другой. универсальный. "пригласите специалиста" (с).

sava1 Подменю пользователя
сообщение 18.09.12, 15:57
Сообщение #6

Живет на форуме
Иконка группы
Группа: Местный
Сообщений: 2684
Из: Проскуров
Спасибо сказали: 678 раз
Рейтинг: 656.7

Прямой запрос к таблицам - там по-фигу какого типа и т.д

Спасибо сказали: awp,

alex040269 Подменю пользователя
сообщение 18.09.12, 15:59
Сообщение #7

Крутой
Иконка группы
Группа: Местный
Сообщений: 1626
Из: Гуляйполе
Спасибо сказали: 236 раз
Рейтинг: 0

Цитата(sava1 @ 18.09.12, 16:57) *
Прямой запрос к таблицам - там по-фигу какого типа и т.д

к каким таблицам?


Signature
Никогда не бойся делать то, что не умеешь, помни - Ноев ковчег был построен любителем, профессионалы построили Титаник.
ЗиУП

mister-x Подменю пользователя
сообщение 18.09.12, 16:07
Сообщение #8

...
Иконка группы
Модератору Про1С (за заслуги в 2011 году)
Группа: Местный
Сообщений: 3477
Из: Тернопіль
Спасибо сказали: 1417 раз
Рейтинг: 0

фільтри по н-субконто і іншим характеристикам рахунків мають бути присутні на формі?

awp Подменю пользователя
сообщение 18.09.12, 16:25
Сообщение #9

Почти ветеран
Иконка группы
Группа: Местный
Сообщений: 520
Спасибо сказали: 70 раз
Рейтинг: 51.3

Цитата(Cthulhu @ 18.09.12, 16:48) *
особенно слова " отчет по всем счетам(субсчетам) и субконто развернуто" и "примерно".
да, неинформативно. а потом и с излишними брызгами - что зря, можно было просто ответить на уточняющие вопросы.
конечно, есть другой. универсальный. "пригласите специалиста" (с).


Цитата
особенно слова " отчет по всем счетам(субсчетам) и субконто развернуто" и "примерно".

Както по другому это можно понять?
к томуже шапка была описана! смотриТе первый пост.

Цитата(Cthulhu @ 18.09.12, 16:48) *
а потом и с излишними брызгами - что зря, можно было просто ответить на уточняющие вопросы.


Если Вам показалось или повиделось БРЫЗГИ - прошу прошения!


а Типы Субконто для каждого счета - куда-с пихать?
неважно!
а НЕвалютные счета?
тудаже - только поле Валюта и сумма по валюте пустые
а колонки для не-валютных сумм?
я же написал СКД() СКК()
а кол-во не нужно?
Нет раз не указал
а признак забалансового счета?
неважно !
а как со счетами-группами - не выводить вообще?
уточняюще было написано по субсчетам
а какое сальдо по оборотным субконто? (и как в резултате это всё в отчете выглядеть должно?)
СКД()

Мне кажется что в первом посте я все информативно написал. Вы же ответили кучей вопросов причем не существенных и кучей вставок которые я так и не вкурил.

конечно, есть другой. универсальный. "пригласите специалиста" (с).

Я готов оплатить Ваши услуги! Вы специалист?

Цитата(mister-x @ 18.09.12, 17:07) *
фільтри по н-субконто і іншим характеристикам рахунків мають бути присутні на формі?

нет
Мне не нужен готовій отчет - просто подскажите куда копать smile.gif

Цитата(alex040269 @ 18.09.12, 16:59) *
к каким таблицам?

Думаю тут. Счас помотрим что к чему


#==TABLE no 286    : Итоги
# Name    |Descr                         |Type[A/S/U]|DBTableName|ReUsable  
T=1SBKTTLC|Итоги                         |A          |1SBKTTLC   |1        
#-----Fields-------
# Name      |Descr               |Type|Length|Precision
F=DATE      |Period              |D   |8     |0        
F=ACCDTID   |AccountDt Id        |C   |9     |0        
F=ACCKTID   |AccountKt Id        |C   |9     |0        
F=CURRID    |Currency Id         |C   |9     |0        
F=KIND      |Total kind          |C   |1     |0        
F=OB1       |Total turnover      |C   |15    |0        
F=OB2       |Total turnover      |C   |15    |0        
F=OB3       |Total turnover      |C   |15    |0        
F=DTFLAGS   |                    |N   |1     |0        
F=KTFLAGS   |                    |N   |1     |0        
F=PLANID    |                    |C   |4     |0        
#----Indexes------
# Name     |Descr         |Unique|Indexed fields                                              |DBName    
I=ACCDT1   |              |0     |DATE,KIND,ACCDTID,ACCKTID,CURRID                            |ACCDT1    
I=ACCKT1   |              |0     |DATE,KIND,ACCKTID,ACCDTID,CURRID                            |ACCKT1    
#
#===============================================================================
#==TABLE no 287    : Остатки
# Name    |Descr                         |Type[A/S/U]|DBTableName|ReUsable  
T=1SBKTTL |Остатки                       |A          |1SBKTTL    |1        
#-----Fields-------
# Name      |Descr               |Type|Length|Precision
F=DATE      |Period              |D   |8     |0        
F=ACCID     |AccountDt Id        |C   |9     |0        
F=CURRID    |Currency Id         |C   |9     |0        
F=KIND      |Total kind          |C   |1     |0        
F=OBDT1     |Total turnover DT   |C   |15    |0        
F=OBKT1     |Total turnover KT   |C   |15    |0        
F=OBDT2     |Total turnover DT   |C   |15    |0        
F=OBKT2     |Total turnover KT   |C   |15    |0        
F=OBDT3     |Total turnover DT   |C   |15    |0        
F=OBKT3     |Total turnover KT   |C   |15    |0        
F=SD        |Saldo               |C   |15    |0        
F=FLAGS     |                    |N   |1     |0        
F=PLANID    |                    |C   |4     |0        
F=VSC0      |                    |C   |4     |0        
F=SC0       |                    |C   |13    |0        
F=OSC0      |                    |N   |1     |0        
F=VSC1      |                    |C   |4     |0        
F=SC1       |                    |C   |13    |0        
F=OSC1      |                    |N   |1     |0        
F=VSC2      |                    |C   |4     |0        
F=SC2       |                    |C   |13    |0        
F=OSC2      |                    |N   |1     |0        
F=VSC3      |                    |C   |4     |0        
F=SC3       |                    |C   |13    |0        
F=OSC3      |                    |N   |1     |0


Сообщение отредактировал awp - 18.09.12, 16:29


Signature
Бухгалтер - это не профессия! Это диагноз!

mister-x Подменю пользователя
сообщение 18.09.12, 16:41
Сообщение #10

...
Иконка группы
Модератору Про1С (за заслуги в 2011 году)
Группа: Местный
Сообщений: 3477
Из: Тернопіль
Спасибо сказали: 1417 раз
Рейтинг: 0

щось на кшталт типових звітів ОСВ і ОСВ по рахунку?

awp Подменю пользователя
сообщение 18.09.12, 16:51
Сообщение #11

Почти ветеран
Иконка группы
Группа: Местный
Сообщений: 520
Спасибо сказали: 70 раз
Рейтинг: 51.3

Цитата(mister-x @ 18.09.12, 17:41) *
щось на кшталт типових звітів ОСВ і ОСВ по рахунку?


Да какбы так.



Signature
Бухгалтер - это не профессия! Это диагноз!

mister-x Подменю пользователя
сообщение 18.09.12, 16:55
Сообщение #12

...
Иконка группы
Модератору Про1С (за заслуги в 2011 году)
Группа: Местный
Сообщений: 3477
Из: Тернопіль
Спасибо сказали: 1417 раз
Рейтинг: 0

отже, напрямок я дав? там для 3-х субконто реалізовано, вам треба в циклі перебрати всі можливі субконто

Сообщение отредактировал mister-x - 18.09.12, 16:58

awp Подменю пользователя
сообщение 18.09.12, 17:08
Сообщение #13

Почти ветеран
Иконка группы
Группа: Местный
Сообщений: 520
Спасибо сказали: 70 раз
Рейтинг: 51.3

Цитата(mister-x @ 18.09.12, 17:55) *
отже, напрямок я дав? там для 3-х субконто реалізовано, вам треба в циклі перебрати всі можливі субконто


Ограничивая по 4 за один запрос - это долго по времени будет



Signature
Бухгалтер - это не профессия! Это диагноз!

Cthulhu Подменю пользователя
сообщение 18.09.12, 18:51
Сообщение #14

Завсегдатай
Иконка группы
Группа: Местный
Сообщений: 224
Из: не ту страну назвали Гондурасом
Спасибо сказали: 83 раз
Рейтинг: 0

// Модуль Формы внешней обработки
//    На Форме должны наличествовать:
//        - ТаблицаЗначений с наименованием ПечТЗ;
//        - Кнопка с формулой "Сформировать()" (без кавычек)

Перем МаксКвоСубконто,тхтКолСубконто, СумДлина,СумТочн,СумФрмт,ВалСумДлина,ВалСумТочн,ВалСумФрмт;

//==============================================================================
Процедура ДобавитьСтрокуДанныхПоТекРазвороту(тБухИт,тПечТЗ,тКвоСубконто,тВалюта="")
    тПечТЗ.НоваяСтрока(); тПечТЗ.ПолучитьСтрокуПоНомеру(тПечТЗ.КоличествоСтрок());
    тПечТЗ.Счет=тБухит.Счет; Для СчСубконто=1 По тКвоСубконто
    Цикл тПечТЗ.УстановитьЗначение(тПечТЗ.НомерСтроки,"Субконто"+СчСубконто,тБухИт.Субконто(СчСубконто)) КонецЦикла;
    тПечТЗ.СуммаДт=тБухит.СКД("С"); тПечТЗ.СуммаКт=тБухит.СКК("С");
    тПечТЗ.Валюта=тВалюта; Если ПустоеЗначение(тВалюта)<>1
    Тогда тПечТЗ.ВалСуммаДт=тБухИт.СКД("В"); тПечТЗ.ВалСуммаКт=тБухИт.СКК("В"); КонецЕсли;
КонецПроцедуры //ДобавитьСтрокуДанныхПоТекРазвороту
//------------------------------------------------------------------------------
Процедура ДоРазвернутьПоСубконто(тБухит,тКвоСубконто,тПечТЗ,ТекВыбСубконто=1)
    Если ТекВыбСубконто<=тКвоСубконто Тогда
        тБухит.ВыбратьСубконто(); Пока тБухит.ПолучитьСубконто()<>0
        Цикл ДоРазвернутьПоСубконто(тБухит,тКвоСубконто,тПечТЗ,ТекВыбСубконто+1) КонецЦикла;
    ИначеЕсли тБухИт.Счет.Валютный<>0 Тогда
        тБухит.ВыбратьВалюты(); Пока тБухит.ПолучитьВалюту()<>0
        Цикл ДобавитьСтрокуДанныхПоТекРазвороту(тБухИт,тПечТЗ,тКвоСубконто,тБухИт.Валюта) КонецЦикла;
    Иначе ДобавитьСтрокуДанныхПоТекРазвороту(тБухИт,тПечТЗ,тКвоСубконто) КонецЕсли;
КонецПроцедуры //ДоРазвернутьПоСубконто
//------------------------------------------------------------------------------
Процедура Сформировать()
    Перем тБухИт,счСубконто;
    тБухит=СоздатьОбъект("БухгалтерскиеИтоги");
    Для счСубконто=1 По МаксКвоСубконто Цикл тБухИт.ИспользоватьСубконто(,,1,0) КонецЦикла;
    тБухит.ВключатьСубсчета(-1); тБухит.ВыполнитьЗапрос(,ВыбДата,,,,"СВ",,3);
    тБухИт.ВыбратьСчета(); Пока тБухИт.ПолучитьСчет()<>0
    Цикл ДоРазвернутьПоСубконто(тБухИт,тБухит.Счет.КоличествоСубконто(),ПечТЗ) КонецЦикла;
    Если ПечТЗ.КоличествоСтрок()<>0 Тогда
        ПечТЗ.Сортировать("+Счет,"+тхтКолСубконто,1); ПечТЗ.ТекущаяСтрока(1);
    КонецЕсли;
КонецПроцедуры //Сформировать
//==============================================================================

ВалСумДлина=Метаданные.ДлинаВалютнойСуммыПроводки; ВалСумТочн=Метаданные.ТочностьВалютнойСуммыПроводки;
Валфрмт="Ч"+ВалСумДлина+"."+ВалСумТочн+", ";

СумДлина=Метаданные.ДлинаСуммыПроводки; СумТочн=Метаданные.ТочностьСуммыПроводки;
СумФрмт="Ч"+СумДлина+"."+СумТочн+", ";

ПечТЗ.Очистить();
ПечТЗ.НоваяКолонка("Счет","Счет",,,"Счет",7);
тхтКолСубконто=""; Для МаксКвоСубконто=1 По Метаданные.МаксимальноеКоличествоСубконто Цикл
    тхтКолСубконто=тхтКолСубконто+"Субконто"+МаксКвоСубконто+",";
    ПечТЗ.НоваяКолонка("Субконто"+МаксКвоСубконто,,,,"Субконто#"+МаксКвоСубконто,31);
КонецЦикла; МаксКвоСубконто=МаксКвоСубконто-1;
ПечТЗ.НоваяКолонка("СуммаДт","Число",СумДлина,СумТочн,"Дт-Сальдо",СумДлина+1,СумФрмт,2);
ПечТЗ.НоваяКолонка("СуммаКт","Число",СумДлина,СумТочн,"Кт-Сальдо",СумДлина+1,СумФрмт,2);
ПечТЗ.НоваяКолонка("Валюта","Справочник.Валюты",,,"в Вал.",12);
ПечТЗ.НоваяКолонка("ВалСуммаДт","Число",ВалСумДлина,ВалСумТочн,"=Дт-Сальдо",ВалСумДлина,ВалСумФрмт,2);
ПечТЗ.НоваяКолонка("ВалСуммаКт","Число",ВалСумДлина,ВалСумТочн,"=Кт-Сальдо",ВалСумДлина,ВалСумФрмт,2);
тхтКолСубконто=Лев(тхтКолСубконто,СтрДлина(тхтКолСубконто)-1);


навскидку, в ожидании такси.. smile.gif
прим: дальше что надо - разобраться нетрудно, я надеюсь?..


Сообщение отредактировал Cthulhu - 19.09.12, 13:34

Спасибо сказали: awp, vadim007,

awp Подменю пользователя
сообщение 18.09.12, 22:04
Сообщение #15

Почти ветеран
Иконка группы
Группа: Местный
Сообщений: 520
Спасибо сказали: 70 раз
Рейтинг: 51.3

Красивый код!
Цитата(Cthulhu @ 18.09.12, 19:51) *
Процедура ДоРазвернутьПоСубконто(тБухит,тКвоСубконто,тПечТЗ,ТекВыбСубконто=1)
    Если ТекВыбСубконто<=тКвоСубконто Тогда
        тБухит.ВыбратьСубконто(); Пока тБухит.ПолучитьСубконто()<>0
        Цикл ДоРазвернутьПоСубконто(тБухит,тКвоСубконто,тПечТЗ,ТекВыбСубконто+1) КонецЦикла;
    ИначеЕсли тБухИт.Счет.Валютный<>0 Тогда
        тБухит.ВыбратьВалюты(); Пока тБухит.ПолучитьВалюту()<>0
        Цикл ДобавитьСтрокуДанныхПоТекРазвороту(тБухИт,тПечТЗ,тКвоСубконто,тБухИт.Валюта) КонецЦикла;
    Иначе ДобавитьСтрокуДанныхПоТекРазвороту(тБухИт,тПечТЗ,тКвоСубконто) КонецЕсли;
КонецПроцедуры //ДоРазвернутьПоСубконто


Огромное спасибо! очень помогли.

Мне даже в голову не приходило попробовать использовать
ИспользоватьСубконто
без указания вида субконто. Для интереса запустил поиск по всей конфе - нет подобного.

Пиво? ....

Сообщение отредактировал awp - 19.09.12, 6:49


Signature
Бухгалтер - это не профессия! Это диагноз!

sava1 Подменю пользователя
сообщение 19.09.12, 7:07
Сообщение #16

Живет на форуме
Иконка группы
Группа: Местный
Сообщений: 2684
Из: Проскуров
Спасибо сказали: 678 раз
Рейтинг: 656.7

Прямой запрос по проводкам (для примера (по 3 субконто)):

    ВсеСубконто = ""; ВсСкД=""; ВсСкК="";
    Для ъ = 1 По 3 Цикл
        ВсСкД=ВсСкД+",DTSC"+(ъ-1)+" [СубкД"+ъ+" :Subconto],VDTSC"+(ъ-1)+" СубкД"+ъ+"_вид";
        ВсСкК=ВсСкК+",KTSC"+(ъ-1)+" [СубкК"+ъ+" :Subconto],VKTSC"+(ъ-1)+" СубкК"+ъ+"_вид";
    КонецЦикла;
    ВсеСубконто = ВсСкД+ВсСкК;

    запрос = БазаД.НовыйЗапрос();        
    текст="
    |select date ДатаПр,sum [Сум :Number.19.2], amount [Кво :Number.19.3], accdtid [СчД :Счет.Основной], accktid [СчК :Счет.Основной]"+ВсеСубконто+"
    |from __1s_entry
    |where Date BETWEEN @НачДата AND @КонДата     
    |and sp4373 = @OurFirm    
    |and accktid = @СчВД
    |and ktsc1 = @пВД" + УслДт +"
    |and amount<>0";    
    запрос.Подготовить(текст);



 ! 

Выделяйте код!
 


Сообщение отредактировал MATEVI - 19.09.12, 8:01

Спасибо сказали: awp,

Не нашли ответа на свой вопрос?
Зарегистрируйтесь и задайте новый вопрос.


Ответить Новая тема
1 чел. читают эту тему (гостей: 1, скрытых пользователей: 0)
Пользователей: 0

 

RSS Текстовая версия Сейчас: 28.03.24, 18:19
1С Предприятие 8.3, 1С Предприятие 8.2, 1С Предприятие 8.1, 1С Предприятие 8.0, 1С Предприятие 7.7, Литература 1С, Общие вопросы по администрированию 1С, Методическая поддержка 1С - всё в одном месте: на Украинском 1С форуме!