Есть отчет ВедомостьДенежныеСредства нужно сделать чтобы кассу видели только ответственный за кассу. Сейчас видно все кассы. Я так понял он еще лезт в другой отчет " Универсальный"
Помогите

[необходимо зарегистрироваться для просмотра ссылки]
[необходимо зарегистрироваться для просмотра ссылки]

Сообщение отредактировал Vofka - 30.03.17, 12:35

burza, вы ожидаете, что кому-то заняться будет нечем и он вам сделает то, что вы хотите?

Vofka @ Сегодня, 13:35 ,
Нет я хочу что вы подсказали где это смотреть

Нужно описать запрос с жестким отбором по кассе. Либо вообще новый отчет сделать.

Vofka @ Сегодня, 14:01 ,
тут пользователь кассы не справочник пользователь а физ.лица тое сть через текущего пользователя не получаеться

Ну так и в чем вопрос/проблема, не пойму?

Vofka @ Сегодня, 14:10 ,
какой параметр прописать для определения физ.лица как пользователя

Можно добавить новую настройку для пользователей, где указывать какое это физ. лицо. Соответственно, брать потом оттуда.

Добавить новую роль Кассир и только ему дать права, у остальных (Пользователь) забрать, если есть.
Можно (через зад) поиграться с подразделениями, но не факт, что сбудется.

Или закрыть встроенный вооще, добавить внешний и ему через Группы дать доступ.

sava1 @ Сегодня, 15:15 ,
Дал права на чтение касс Текущий пользователь. все ровно видно все кассы пользователю

У пользователя есть реквизит "Физ. лицо" заполняйте его и делайте отбор по физ лицу, определив текущего пользователя а из него уже берите физ лицо

В универсальном отчете я так понимаю надо смотреть. Покажите хотя бы где имено надо смотреть в отчете

Универсальный отчет не советую трогать. НИКОГДА. Поломаете его и потом перестанут работать половина отчетов в системе, т.к. большая часть отчетов на нем написана...
В Вашем случае нужно в отчете убрать признак построения по регистру, закомментировать

//УниверсальныйОтчет.ИмяРегистра = "ДенежныеСредства"

далее добавить текст запроса, в котором будете выбирать данные из РН.ДенежныеСредства по всем стандартам универсального отчета (советую посмотреть как это сделано в типовом отчете, например "Валовая прибыль"). Сделайте запрос по аналогии, в запросе свяжите РН.ДенежныеСредства с РС.ОтветственныеЛица по кассе и передайте параметром в запрос ваше физ. лицо.

Проще говоря чтобы не ломать существующий отчет, лучше на его основе сделайте новый, за пример возьмите "Валовую прибыль", все что Вам нужно находится в процедуре "УстановитьНачальныеНастройки"

Bernet @ Сегодня, 17:14 ,
Прошу вас написать запрос. мне очень надо.

Сделал вот так

ВЫБРАТЬ
    ДенежныеСредстваОстаткиИОбороты.СуммаНачальныйОстаток,
    ДенежныеСредстваОстаткиИОбороты.СуммаКонечныйОстаток,
    ДенежныеСредстваОстаткиИОбороты.СуммаПриход,
    ДенежныеСредстваОстаткиИОбороты.СуммаРасход,
    ДенежныеСредстваОстаткиИОбороты.БанковскийСчетКасса
ИЗ
    РегистрНакопления.ДенежныеСредства.ОстаткиИОбороты КАК ДенежныеСредстваОстаткиИОбороты
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ОтветственныеЛица.СрезПоследних КАК ОтветственныеЛицаСрезПоследних
        ПО ДенежныеСредстваОстаткиИОбороты.БанковскийСчетКасса.Наименование = ОтветственныеЛицаСрезПоследних.СтруктурнаяЕдиница.Наименование
ГДЕ
    ОтветственныеЛицаСрезПоследних.ФизическоеЛицо = &ФизическоеЛицо

как сюда отбор по физ лицу добавить без выбора самому

вот такое или близко )

     Запрос = новый Запрос;
Запрос.УстановитьПараметр("ФизическоеЛицо",СсылкаНаОбъект.ФизическоеЛицо);

Запрос.Текст = "ВЫБРАТЬ
|    ДенежныеСредстваОстаткиИОбороты.СуммаНачальныйОстаток,
|    ДенежныеСредстваОстаткиИОбороты.СуммаКонечныйОстаток,
|    ДенежныеСредстваОстаткиИОбороты.СуммаПриход,
|    ДенежныеСредстваОстаткиИОбороты.СуммаРасход,
|    ДенежныеСредстваОстаткиИОбороты.БанковскийСчетКасса
|ИЗ
|    РегистрНакопления.ДенежныеСредства.ОстаткиИОбороты КАК ДенежныеСредстваОстаткиИОбороты
|        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ОтветственныеЛица.СрезПоследних КАК ОтветственныеЛицаСрезПоследних
|        ПО ДенежныеСредстваОстаткиИОбороты.БанковскийСчетКасса.Наименование = ОтветственныеЛицаСрезПоследних.СтруктурнаяЕдиница.Наименование
|ГДЕ
|    ОтветственныеЛицаСрезПоследних.ФизическоеЛицо = &ФизическоеЛицо";

burza @ Вчера, 21:48 ,
почитайте за отчеты на основе универсального и с чем их едят. Вы пробовали отчет с таким запросом запускать? у вас потом ни вложенных полей, ни свойств, ни категорий видно не будет.

Запрос должен быть таким:

Процедура УстановитьНачальныеНастройки(ДополнительныеПараметры = Неопределено) Экспорт
    
    // Настройка общих параметров универсального отчета
    
    // Содержит название отчета, которое будет выводиться в шапке.
    // Тип: Строка.
    // Пример:
    // УниверсальныйОтчет.мНазваниеОтчета = "Название отчета";
    УниверсальныйОтчет.мНазваниеОтчета = СокрЛП(ЭтотОбъект.Метаданные().Синоним);
    
    // Содержит признак необходимости отображения надписи и поля выбора раздела учета в форме настройки.
    // Тип: Булево.
    // Значение по умолчанию: Истина.
    // Пример:
    // УниверсальныйОтчет.мВыбиратьИмяРегистра = Ложь;
    УниверсальныйОтчет.мВыбиратьИмяРегистра = Ложь;
    
    // Содержит имя регистра, по метаданным которого будет выполняться заполнение настроек отчета.
    // Тип: Строка.
    // Пример:
    // УниверсальныйОтчет.ИмяРегистра = "ТоварыНаСкладах";
    //УниверсальныйОтчет.ИмяРегистра = "ДенежныеСредства";
    
    // Содержит признак необходимости вывода отрицательных значений показателей красным цветом.
    // Тип: Булево.
    // Значение по умолчанию: Ложь.
    // Пример:
    // УниверсальныйОтчет.ОтрицательноеКрасным = Истина;
    
    // Содержит признак необходимости вывода в отчет общих итогов.
    // Тип: Булево.
    // Значение по умолчанию: Истина.
    // Пример:
    // УниверсальныйОтчет.ВыводитьОбщиеИтоги = Ложь;
    
    // Содержит признак необходимости вывода детальных записей в отчет.
    // Тип: Булево.
    // Значение по умолчанию: Ложь.
    // Пример:
    // УниверсальныйОтчет.ВыводитьДетальныеЗаписи = Истина;
    
    // Содержит признак необходимости отображения флага использования свойств и категорий в форме настройки.
    // Тип: Булево.
    // Значение по умолчанию: Истина.
    // Пример:
    // УниверсальныйОтчет.мВыбиратьИспользованиеСвойств = Ложь;
    УниверсальныйОтчет.мВыбиратьИспользованиеСвойств = Истина;
    
    // Содержит признак использования свойств и категорий при заполнении настроек отчета.
    // Тип: Булево.
    // Значение по умолчанию: Ложь.
    // Пример:
    // УниверсальныйОтчет.ИспользоватьСвойстваИКатегории = Истина;
    
    // Содержит признак использования простой формы настроек отчета без группировок колонок.
    // Тип: Булево.
    // Значение по умолчанию: Ложь.
    // Пример:
    // УниверсальныйОтчет.мРежимФормыНастройкиБезГруппировокКолонок = Истина;
    
    // Дополнительные параметры, переданные из отчета, вызвавшего расшифровку.
    // Информация, передаваемая в переменной ДополнительныеПараметры, может быть использована
    // для реализации специфичных для данного отчета параметрических настроек.
    
    
    УниверсальныйОтчет.ПостроительОтчета.Текст = "ВЫБРАТЬ РАЗРЕШЕННЫЕ
    |    ДенежныеСредстваОстаткиИОбороты.Регистратор КАК Регистратор,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодДень КАК ПериодДень,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодНеделя КАК ПериодНеделя,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодДекада КАК ПериодДекада,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодМесяц КАК ПериодМесяц,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодКвартал КАК ПериодКвартал,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодПолугодие КАК ПериодПолугодие,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодГод КАК ПериодГод,
    |    ДенежныеСредстваОстаткиИОбороты.ВидДенежныхСредств КАК ВидДенежныхСредств,
    |    ДенежныеСредстваОстаткиИОбороты.БанковскийСчетКасса КАК БанковскийСчетКасса,
    |    ДенежныеСредстваОстаткиИОбороты.Организация КАК Организация,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаНачальныйОстаток КАК СуммаНачальныйОстаток,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаКонечныйОстаток КАК СуммаКонечныйОстаток,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаОборот КАК СуммаОборот,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаПриход КАК СуммаПриход,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаРасход КАК СуммаРасход,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаУпрНачальныйОстаток КАК СуммаУпрНачальныйОстаток,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаУпрКонечныйОстаток КАК СуммаУпрКонечныйОстаток,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаУпрПриход КАК СуммаУпрПриход,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаУпрОборот КАК СуммаУпрОборот,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаУпрРасход КАК СуммаУпрРасход
    |    //ПОЛЯ_СВОЙСТВА
    |    //ПОЛЯ_КАТЕГОРИИ
    |{ВЫБРАТЬ
    |    Регистратор.*,
    |    ПериодДень,
    |    ПериодНеделя,
    |    ПериодДекада,
    |    ПериодМесяц,
    |    ПериодКвартал,
    |    ПериодПолугодие,
    |    ПериодГод,
    |    ВидДенежныхСредств.*,
    |    БанковскийСчетКасса.*,
    |    Организация.*,
    |    СуммаНачальныйОстаток,
    |    СуммаКонечныйОстаток,
    |    СуммаОборот,
    |    СуммаПриход,
    |    СуммаРасход,
    |    СуммаУпрНачальныйОстаток,
    |    СуммаУпрКонечныйОстаток,
    |    СуммаУпрПриход,
    |    СуммаУпрОборот,
    |    СуммаУпрРасход
    |    //ПСЕВДОНИМЫ_СВОЙСТВА
    |    //ПСЕВДОНИМЫ_КАТЕГОРИИ
    |}
    |ИЗ
    |    РегистрНакопления.ДенежныеСредства.ОстаткиИОбороты(&ДатаНач, &ДатаКон, Авто, ,{ВидДенежныхСредств.* КАК ВидДенежныхСредств, БанковскийСчетКасса.* КАК БанковскийСчетКасса, Организация.* КАК Организация} ) КАК ДенежныеСредстваОстаткиИОбороты
    |    ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ОтветственныеЛица.СрезПоследних(&ДатаКон, ) КАК ОтветственныеЛица
    |        ПО ОтветственныеЛица.СтруктурнаяЕдиница = ДенежныеСредстваОстаткиИОбороты.БанковскийСчетКасса
    |    //СОЕДИНЕНИЯ
    |ГДЕ
    |    ОтветственныеЛица.ФизическоеЛицо = &ФизЛицо    
    |{ГДЕ
    |    ДенежныеСредстваОстаткиИОбороты.Регистратор.*,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодДень,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодНеделя,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодДекада,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодМесяц,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодКвартал,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодПолугодие,
    |    ДенежныеСредстваОстаткиИОбороты.ПериодГод,
    |    ДенежныеСредстваОстаткиИОбороты.ВидДенежныхСредств.*,
    |    ДенежныеСредстваОстаткиИОбороты.БанковскийСчетКасса.*,
    |    ДенежныеСредстваОстаткиИОбороты.Организация.*,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаНачальныйОстаток,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаКонечныйОстаток,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаОборот,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаПриход,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаРасход,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаУпрНачальныйОстаток,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаУпрКонечныйОстаток,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаУпрПриход,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаУпрОборот,
    |    ДенежныеСредстваОстаткиИОбороты.СуммаУпрРасход
    |    //УСЛОВИЯ_СВОЙСТВА
    |    //УСЛОВИЯ_КАТЕГОРИИ
    |}
    |{УПОРЯДОЧИТЬ ПО
    |    Регистратор.*,
    |    ПериодДень,
    |    ПериодНеделя,
    |    ПериодДекада,
    |    ПериодМесяц,
    |    ПериодКвартал,
    |    ПериодПолугодие,
    |    ПериодГод,
    |    ВидДенежныхСредств.*,
    |    БанковскийСчетКасса.*,
    |    Организация.*,
    |    СуммаНачальныйОстаток,
    |    СуммаКонечныйОстаток,
    |    СуммаОборот,
    |    СуммаПриход,
    |    СуммаРасход,
    |    СуммаУпрНачальныйОстаток,
    |    СуммаУпрКонечныйОстаток,
    |    СуммаУпрПриход,
    |    СуммаУпрОборот,
    |    СуммаУпрРасход
    |    //ПСЕВДОНИМЫ_СВОЙСТВА
    |    //ПСЕВДОНИМЫ_КАТЕГОРИИ
    |}
    |ИТОГИ
    |    СУММА(СуммаНачальныйОстаток),
    |    СУММА(СуммаКонечныйОстаток),
    |    СУММА(СуммаОборот),
    |    СУММА(СуммаПриход),
    |    СУММА(СуммаРасход),
    |    СУММА(СуммаУпрНачальныйОстаток),
    |    СУММА(СуммаУпрКонечныйОстаток),
    |    СУММА(СуммаУпрПриход),
    |    СУММА(СуммаУпрОборот),
    |    СУММА(СуммаУпрРасход)    
    |    //ИТОГИ_СВОЙСТВА
    |    //ИТОГИ_КАТЕГОРИИ
    |ПО
    |    ОБЩИЕ
    |{ИТОГИ ПО
    |    Регистратор.*,
    |    ПериодДень,
    |    ПериодНеделя,
    |    ПериодДекада,
    |    ПериодМесяц,
    |    ПериодКвартал,
    |    ПериодПолугодие,
    |    ПериодГод,
    |    ВидДенежныхСредств.*,
    |    БанковскийСчетКасса.*,
    |    Организация.*
    |    //ПСЕВДОНИМЫ_СВОЙСТВА
    |    //ПСЕВДОНИМЫ_КАТЕГОРИИ
    |}
    |";
    
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("Регистратор", "Регистратор");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("ПериодДень", "Период день");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("ПериодНеделя", "Период неделя");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("ПериодДекада", "Период декада");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("ПериодМесяц", "Период месяц");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("ПериодКвартал", "Период квартал");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("ПериодПолугодие", "Период полугодие");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("ПериодГод", "Период год");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("ВидДенежныхСредств", "Вид денежных средств");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("БанковскийСчетКасса", "Банковский счет/касса");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("Организация", "Организация");
    
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("СуммаНачальныйОстаток", "Сумма начальный остаток");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("СуммаКонечныйОстаток", "Сумма конечный остаток");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("СуммаОборот", "Сумма оборот");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("СуммаПриход", "Сумма приход");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("СуммаРасход", "Сумма расход");
    
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("СуммаУпрНачальныйОстаток", "Сумма упр начальный остаток");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("СуммаУпрКонечныйОстаток", "Сумма упр конечный остаток");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("СуммаУпрОборот", "Сумма упр оборот");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("СуммаУпрПриход", "Сумма упр приход");
    УниверсальныйОтчет.мСтруктураПредставлениеПолей.Вставить("СуммаУпрРасход", "Сумма упр расход");
    
    
    //УниверсальныйОтчет.ДобавитьПолеГруппировка("Организация",           "БанковскийСчетКасса", "Владелец",              "Организация");
    УниверсальныйОтчет.ДобавитьПолеГруппировка("ВалютаДенежныхСредств", "БанковскийСчетКасса", "ВалютаДенежныхСредств", "Валюта счета (кассы)");
    
    // Заполнение начальных настроек универсального отчета
    //УниверсальныйОтчет.УстановитьНачальныеНастройки(Истина);
    
    УниверсальныйОтчет.ДобавитьПоказатель("СуммаНачальныйОстаток", "Начальный остаток", Истина, "ЧЦ=15; ЧДЦ=2", "Сумма", "Сумма в валюте счета (кассы)");
    УниверсальныйОтчет.ДобавитьПоказатель("СуммаПриход",           "Приход",            Истина, "ЧЦ=15; ЧДЦ=2", "Сумма", "Сумма в валюте счета (кассы)");
    УниверсальныйОтчет.ДобавитьПоказатель("СуммаРасход",           "Расход",            Истина, "ЧЦ=15; ЧДЦ=2", "Сумма", "Сумма в валюте счета (кассы)");
    УниверсальныйОтчет.ДобавитьПоказатель("СуммаКонечныйОстаток",  "Конечный остаток",  Истина, "ЧЦ=15; ЧДЦ=2", "Сумма", "Сумма в валюте счета (кассы)");
    УниверсальныйОтчет.ДобавитьПоказатель("СуммаОборот",           "Оборот",              Ложь, "ЧЦ=15; ЧДЦ=2", "Сумма", "Сумма в валюте счета (кассы)");
    
    ВалютаУпр = глЗначениеПеременной("ВалютаУправленческогоУчета");
    УниверсальныйОтчет.ДобавитьПоказатель("СуммаУпрНачальныйОстаток", "Начальный остаток", Истина, "ЧЦ=15; ЧДЦ=2", "СуммаУпр", "Сумма в (" + ВалютаУпр + ")");
    УниверсальныйОтчет.ДобавитьПоказатель("СуммаУпрПриход",           "Приход",            Истина, "ЧЦ=15; ЧДЦ=2", "СуммаУпр", "Сумма в (" + ВалютаУпр + ")");
    УниверсальныйОтчет.ДобавитьПоказатель("СуммаУпрРасход",           "Расход",            Истина, "ЧЦ=15; ЧДЦ=2", "СуммаУпр", "Сумма в (" + ВалютаУпр + ")");
    УниверсальныйОтчет.ДобавитьПоказатель("СуммаУпрКонечныйОстаток",  "Конечный остаток",  Истина, "ЧЦ=15; ЧДЦ=2", "СуммаУпр", "Сумма в (" + ВалютаУпр + ")");
    УниверсальныйОтчет.ДобавитьПоказатель("СуммаУпрОборот",           "Оборот",              Ложь, "ЧЦ=15; ЧДЦ=2", "СуммаУпр", "Сумма в (" + ВалютаУпр + ")");
    
    // Добавление предопределенных группировок строк отчета.
    // Необходимо вызывать для каждой добавляемой группировки строки.
    // УниверсальныйОтчет.ДобавитьИзмерениеСтроки(<ПутьКДанным>);
    УниверсальныйОтчет.ДобавитьИзмерениеСтроки("БанковскийСчетКасса");
    
    // Добавление предопределенных группировок колонок отчета.
    // Необходимо вызывать для каждой добавляемой группировки колонки.
    // УниверсальныйОтчет.ДобавитьИзмерениеКолонки(<ПутьКДанным>);
    
    // Добавление предопределенных отборов отчета.
    // Необходимо вызывать для каждого добавляемого отбора.
    // УниверсальныйОтчет.ДобавитьОтбор(<ПутьКДанным>);
    УниверсальныйОтчет.ДобавитьОтбор("БанковскийСчетКасса");
    УниверсальныйОтчет.ДобавитьОтбор("ВидДенежныхСредств");
    УниверсальныйОтчет.ДобавитьОтбор("ВалютаДенежныхСредств");
    УниверсальныйОтчет.ДобавитьОтбор("Организация");
    
    // Добавление предопределенных полей порядка отчета.
    // Необходимо вызывать для каждого добавляемого поля порядка.
    // УниверсальныйОтчет.ДобавитьПорядок(<ПутьКДанным>);
    
    // Установка связи подчиненных и родительских полей
    // УниверсальныйОтчет.УстановитьСвязьПолей(<ПутьКДанным>, <ПутьКДаннымРодитель>);
    
    // Установка связи полей и измерений
    // УниверсальныйОтчет.УстановитьСвязьПоляИИзмерения(<ИмяПоля>, <ИмяИзмерения>);
    
    // Установка представлений полей
    УниверсальныйОтчет.УстановитьПредставленияПолей(УниверсальныйОтчет.мСтруктураПредставлениеПолей, УниверсальныйОтчет.ПостроительОтчета);
    
    // Заполнение начальных настроек универсального отчета
    УниверсальныйОтчет.УстановитьНачальныеНастройки(Ложь);
    
    // Добавление дополнительных полей
    // Необходимо вызывать для каждого добавляемого дополнительного поля.
    // УниверсальныйОтчет.ДобавитьДополнительноеПоле(<ПутьКДанным>, <Размещение>, <Положение>);
    УниверсальныйОтчет.ДобавитьДополнительноеПоле("ВалютаДенежныхСредств");
    УниверсальныйОтчет.ДобавитьДополнительноеПоле("ВидДенежныхСредств");
    
КонецПроцедуры // УстановитьНачальныеНастройки()

и передать параметр физ лица при формировании

Процедура СформироватьОтчет(ТабличныйДокумент) Экспорт
    
    // Перед формирование отчета можно установить необходимые параметры универсального отчета.
    
    ТекПользователь = глЗначениеПеременной("глТекущийПользователь");
    ФизЛицоСсылка = ?(ЗначениеЗаполнено(ТекПользователь), ТекПользователь.ФизЛицо, Справочники.ФизическиеЛица.ПустаяСсылка());
    
    УниверсальныйОтчет.ПостроительОтчета.Параметры.Вставить("ФизЛицо", ФизЛицоСсылка);
    
    УниверсальныйОтчет.СформироватьОтчет(ТабличныйДокумент);

КонецПроцедуры // СформироватьОтчет()

Bernet @ Сегодня, 10:12 ,
БОЛЬШОЕ ВАМ спасибо!!! Очень выручили)