Функция ПоказательЭлектронныхВесов(НомерВесов=1, документ = Неопределено, Организация = Неопределено, ВидСобытия = Неопределено) Экспорт    
    Перем Вес, ВО;

    Вес = Неопределено;
    МаксимальныйВес = 999999999;

    #Если Клиент Тогда
        Нашли = Ложь;
        ВО=Справочники.ИНАГРО_ВнешнееОборудование.ПустаяСсылка();
        // ищем веса  для конкретного документа :
        Если документ<> Неопределено тогда
            
            МетаданныеДок = документ.Метаданные();
            
            СписокСкладов = Новый СписокЗначений;            
            СписокСкладов.Добавить(Справочники.Склады.ПустаяСсылка());
            Если ИНАГРО_ОбщегоНазначения.ЕстьРеквизитДокумента("Склад",МетаданныеДок) Тогда
                СписокСкладов.Добавить(Документ.Склад);
            КонецЕсли;
            
            запрос= новый запрос;
            строкаМетаданых=Справочники.ИНАГРО_СтруктураМетаданных.НайтиПоРеквизиту("ИмяПоМетаданным", МетаданныеДок.Имя,Справочники.ИНАГРО_СтруктураМетаданных.Документы);
            Запрос.УстановитьПараметр("ИмяКомпьютера",ИмяКомпьютера());
            Запрос.УстановитьПараметр("Документ",СтрокаМетаданых );            
            Запрос.УстановитьПараметр("СписокСкладов",СписокСкладов);
            Запрос.Текст="ВЫБРАТЬ РАЗРЕШЕННЫЕ
                         |    Справочник.Ссылка,
                         |    Регистр.Склад
                         |ИЗ
                         |    РегистрСведений.ИНАГРО_ВнешнееОборудование КАК Регистр
                         |        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ИНАГРО_ВнешнееОборудование КАК справочник
                         |        ПО Регистр.Оборудование = Справочник.Ссылка
                         |ГДЕ
                         |    Справочник.ПометкаУдаления = ЛОЖЬ
                         |    И справочник.ВидОборудования = ЗНАЧЕНИЕ(Перечисление.ИНАГРО_ВидыВнешнегоОборудования.Весы)
                         |    И справочник.ИмяКомпьютера = &ИмяКомпьютера
                         |    И Регистр.Документ = &Документ
                         |    И Регистр.Склад В(&СписокСкладов)";

            
            Выборка = Запрос.Выполнить().Выбрать();            
            Если Выборка.Количество()=0 тогда

            ИначеЕсли Выборка.Количество()=1 тогда 
                Выборка.Следующий();
                ВО=Выборка.Ссылка;
                Нашли =истина;
            ИначеЕсли Выборка.Количество()>1 Тогда 
                Нашли = истина;
                СписокВО = Новый СписокЗначений;
                СписокВОБезСклада = Новый СписокЗначений;     
                Пока Выборка.Следующий() Цикл
                    // Значит В выборке есть ВО с пустым и заполненым складом - ВО с пустым складом будем отбирать отдельно
                    Если ЗначениеЗаполнено(Выборка.Склад) Тогда
                        СписокВО.Добавить(Выборка.ссылка);
                    Иначе 
                        СписокВОБезСклада.Добавить(Выборка.ссылка);
                    КонецЕсли;
                КонецЦикла;
                
                Если СписокВО.Количество() > 0 Тогда
                    СписокВыбора = СписокВО;
                Иначе
                    СписокВыбора = СписокВОБезСклада;
                КонецЕсли;
                Если СписокВыбора.Количество() = 1 Тогда
                    ВыбраныеВесы = СписокВыбора[0];
                Иначе                     
                    ВыбраныеВесы = СписокВыбора.ВыбратьЭлемент("Выберете весы");
                КонецЕсли;
                
                Если ВыбраныеВесы= Неопределено  тогда 
                    Возврат -1;
                Иначе 
                    Во=ВыбраныеВесы.Значение;
                КонецЕсли;
            КонецЕсли;    
        КонецЕсли;
        // если не находим тогда ищем всё что подключено к этому компу :
        если не Нашли тогда     
            Запрос=Новый запрос;
            Запрос.УстановитьПараметр("ИмяКомпьютера",ИмяКомпьютера());
            Запрос.Текст="ВЫБРАТЬ РАЗРЕШЕННЫЕ 
            |    ИНАГРО_ВнешнееОборудование.Ссылка
            |ИЗ
            |    Справочник.ИНАГРО_ВнешнееОборудование КАК ИНАГРО_ВнешнееОборудование
            |ГДЕ
            |    ИНАГРО_ВнешнееОборудование.ПометкаУдаления = ЛОЖЬ
            |    И ИНАГРО_ВнешнееОборудование.ВидОборудования = ЗНАЧЕНИЕ(Перечисление.ИНАГРО_ВидыВнешнегоОборудования.Весы)
            |    И ИНАГРО_ВнешнееОборудование.ИмяКомпьютера = &ИмяКомпьютера";
            
            Выборка=запрос.Выполнить().Выбрать();            
            Если Выборка.Количество()=1 Тогда
                Выборка.Следующий();
                ВО=Выборка.Ссылка;            
            ИначеЕсли Выборка.Количество()>1 Тогда 
                Нашли =истина;
                
                СписокВыбора= Новый СписокЗначений;     
                Пока выборка.Следующий() цикл
                    СписокВыбора.Добавить(Выборка.ссылка);
                КонецЦикла;
                ВыбраныеВесы= СписокВыбора.ВыбратьЭлемент("Выберете весы");
                Если ВыбраныеВесы= Неопределено  тогда 
                    Возврат -1;
                иначе 
                    Во=ВыбраныеВесы.Значение;
                КонецЕсли;
            КонецЕсли;
        КонецЕсли;
        //    если вобще ничего не нашли тогда :
        Если ВО.Пустая() Тогда
            ТекстСообщения=Локализация.СтрШаблон("К компьютеру """"¤1¤"""" не подключено внешнее оборудование",ИмяКомпьютера());
            ОбщегоНазначения.СообщитьОбОшибке(ТекстСообщения);
            Возврат -1;
        КонецЕсли;
        //  обрабатываем найденые веса 
        ОбработкаВесов = Неопределено;
        Если ЗначениеЗаполнено(ВО.Файл) Тогда
            ОбработкаВесов=ВнешниеОбработки.Создать(СокрЛП(ВО.Файл));                
        Иначе
            ИмяФайла = ПолучитьИмяВременногоФайла();
            ДвоичныеДанные = ВО.ХранилищеВнешнейОбработки.Получить();
            Если НЕ ДвоичныеДанные = Неопределено Тогда
                ДвоичныеДанные.Записать(ИмяФайла);
                ОбработкаВесов=ВнешниеОбработки.Создать(ИмяФайла);
                УдалитьФайлы(ИмяФайла);    
            КонецЕсли;
        КонецЕсли;
        Если ОбработкаВесов = Неопределено Тогда
            ТекстСообщения=Локализация.СтрШаблон("Обработка чтения весов для компьютера """"¤1¤"""" не задана",ИмяКомпьютера());
            ОбщегоНазначения.СообщитьОбОшибке(ТекстСообщения);
            Возврат -1;
        КонецЕсли;
        ФормаОбработкиВесов=ОбработкаВесов.ПолучитьФорму();
        
        //---------------------- заполнение параметров внешней обработка----------------
        
        ОбработкаВесов.КвоДатчиков =  ВО.КвоДатчиков;
        ОбработкаВесов.НомерВесов = ВО.Порт2;
        ОбработкаВесов.ФайлДрайвера = ВО.ФайлДрайвера;
        ОбработкаВесов.КаталогФайлаДрайвера = ВО.КаталогФайлаДрайвера;
        // датчик 1
        Если ВО.КвоДатчиков <= 2 Тогда
            ОбработкаВесов.Порт1 = ВО.Порт1;
            ОбработкаВесов.СкоростьПорт1 = ВО.СкоростьПорт1;
            ОбработкаВесов.КвоБитДаныхВБайтеПорт1 = ВО.КвоБитДанныхВБайтеПорт1;
            ОбработкаВесов.РежимПроверкиПарностиПорт1 = ВО.РежимПроверкиПарностиПорт1;
            ОбработкаВесов.КвоКонечныхБитПорт1 = ВО.КвоКонечныхБитПорт1;
            ОбработкаВесов.КодУстройстваПорт1 = ВО.КодУстройстваПорт1;
            ОбработкаВесов.АдресКонтролераВсетиПорт1 = ВО.АдресКонтролераВСетиПорт1;
            ОбработкаВесов.КлючРеестрацииКонтролераПорт1 = ВО.КлючРеестрацииКонтролераПорт1;
        КонецЕсли;
        // датчик 2
        Если ВО.КвоДатчиков = 2 Тогда
            ОбработкаВесов.Порт2 = ВО.Порт2;
            ОбработкаВесов.СкоростьПорт2 = ВО.СкоростьПорт2;
            ОбработкаВесов.КвоБитДаныхВБайтеПорт2 = ВО.КвоБитДанныхВБайтеПорт2;
            ОбработкаВесов.РежимПроверкиПарностиПорт2 = ВО.РежимПроверкиПарностиПорт2;
            ОбработкаВесов.КвоКонечныхБитПорт2 = ВО.КвоКонечныхБитПорт2;
            ОбработкаВесов.КодУстройстваПорт2 = ВО.КодУстройстваПорт2;
            ОбработкаВесов.АдресКонтролераВсетиПорт2 = ВО.АдресКонтролераВСетиПорт2;
            ОбработкаВесов.КлючРеестрацииКонтролераПорт2 = ВО.КлючРеестрацииКонтролераПорт2;
        КонецЕсли;
        //------------------------------------------------------------------------------
        
        Попытка
            
            Если ВО.ОткрыватьМодально Тогда
                Вес = ФормаОбработкиВесов.ОткрытьМодально(2);
            Иначе
                ОбработкаВесов.Сформировать();
                Вес=ОбработкаВесов.Вес;
            КонецЕсли;
            
        Исключение
            
            Сообщить("Весы не стабилизировались");
            
        КонецПопытки;
        
        МаксимальныйВес = ВО.МаксимальныйВес;
        
    #КонецЕсли
    
933 строка    Вес = ?(Вес < 0, 0, Вес);
    // проверка на ошибку
    Если Вес = 0 Тогда
        
        Сообщить("Обнаружен нулевой вес");
        Возврат -1;
                
    ИначеЕсли Вес = Неопределено Тогда        
        
        Возврат -1;
        
    Иначе
        
        Если ИНАГРО_Элеватор.ПолучитьПараметрУчетаЭлеватора(ТекущаяДата(), "КонтролироватьМаксимальнуюГрузоподъемностьВесов", Ложь, Организация) Тогда             
            Если Вес > МаксимальныйВес тогда                 
                Сообщить("Введённый вес превышает допустимую грузоподъемность весов - "+МаксимальныйВес);
                Вес = 0;
            КонецЕсли;            
        КонецЕсли;
        Если ИНАГРО_Элеватор.ПолучитьПараметрУчетаЭлеватора(ТекущаяДата(), "ВключитьИспользованиеКамерыВТерминальномРежиме", Ложь, Организация) Тогда
            СписокВО = Новый СписокЗначений;
            Если ЗначениеЗаполнено(ВО) Тогда
                Если ТипЗнч(ВО) = Тип("СправочникСсылка.ИНАГРО_ВнешнееОборудование") Тогда
                    Для Каждого СтрВо Из ВО.Камеры Цикл
                        Если ЗначениеЗаполнено(СтрВо.Камера) Тогда
                            СписокВО.Добавить(СтрВо.Камера);
                        КонецЕсли;                               
                    КонецЦикла;    
                    ПолучитьСнимок(Документ, ВидСобытия, СписокВО);
                КонецЕсли;
            КонецЕсли;
        КонецЕсли;
        Возврат Вес;
        
    КонецЕсли;
                                                                    
КонецФункции

#Если Клиент Тогда
// Процедура заполняет построитель отчета.
//
Процедура ЗаполнитьПостроительОтчета() Экспорт

    ПостроительОтчета.Параметры.Вставить("ПустаяХарактеристика", Справочники.ХарактеристикиНоменклатуры.ПустаяСсылка());

    ТекстЗапроса = "
    |ВЫБРАТЬ
    |    ИСТИНА КАК Печать,
    |    СпрНоменклатура.Номенклатура КАК Номенклатура,
    |    СпрНоменклатура.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
    |    СпрНоменклатура.Номенклатура.ЕдиницаХраненияОстатков КАК ЕдиницаИзмерения,
    |    0 КАК Цена,
    |    1 КАК Количество
    |ИЗ
    |    (ВЫБРАТЬ
    |        СпрНоменклатура.Ссылка КАК Номенклатура,
    |        &ПустаяХарактеристика КАК ХарактеристикаНоменклатуры
    |    ИЗ
    |        Справочник.Номенклатура КАК СпрНоменклатура
    |    ГДЕ НЕ СпрНоменклатура.ЭтоГруппа
    |    {ГДЕ
    |        СпрНоменклатура.Ссылка.* КАК Номенклатура}
    |    ОБЪЕДИНИТЬ ВСЕ
    |    ВЫБРАТЬ
    |        СпрХарактеристики.Владелец,
    |        СпрХарактеристики.Ссылка
    |    ИЗ
    |        Справочник.ХарактеристикиНоменклатуры КАК СпрХарактеристики
    |    {ГДЕ
    |        СпрХарактеристики.Владелец.* КАК Номенклатура,
    |        СпрХарактеристики.Ссылка.* КАК ХарактеристикаНоменклатуры}
    |    ) КАК СпрНоменклатура
    |";
    
    Если ТолькоИмеющиесяВНаличии Тогда
        ТекстЗапроса = ТекстЗапроса + "
        |ЛЕВОЕ СОЕДИНЕНИЕ
        |    (ВЫБРАТЬ
        |        НаСкладе.Номенклатура,
        |        НаСкладе.ХарактеристикаНоменклатуры,
        |        СУММА(НаСкладе.Количество) КАК Количество
        |    ИЗ
        |        (ВЫБРАТЬ
        |            НаСкладе.Номенклатура,
        |            НаСкладе.ХарактеристикаНоменклатуры,
        |            НаСкладе.КоличествоОстаток КАК Количество
        |        ИЗ
        |            РегистрНакопления.ТоварыНаСкладах.Остатки(, {Номенклатура.* КАК Номенклатура,
        |               ХарактеристикаНоменклатуры.* КАК ХарактеристикаНоменклатуры,
        |               Склад.* КАК Склад}) КАК НаСкладе
        |        ОБЪЕДИНИТЬ ВСЕ
        |        ВЫБРАТЬ
        |            ВРознице.Номенклатура,
        |            ВРознице.ХарактеристикаНоменклатуры,
        |            ВРознице.КоличествоОстаток КАК Количество
        |        ИЗ
        |            РегистрНакопления.ТоварыВРознице.Остатки(, {Номенклатура.* КАК Номенклатура,
        |               ХарактеристикаНоменклатуры.* КАК ХарактеристикаНоменклатуры,
        |               Склад.* КАК Склад}) КАК ВРознице
        |        ОБЪЕДИНИТЬ ВСЕ
        |        ВЫБРАТЬ
        |            ВНТТ.Номенклатура,
        |            ВНТТ.ХарактеристикаНоменклатуры,
        |            ВНТТ.КоличествоОстаток КАК Количество
        |        ИЗ
        |            РегистрНакопления.ТоварыВНТТ.Остатки(, {Номенклатура.* КАК Номенклатура,
        |               ХарактеристикаНоменклатуры.* КАК ХарактеристикаНоменклатуры,
        |               Склад.* КАК Склад}) КАК ВНТТ
        |        ) КАК НаСкладе
        |    СГРУППИРОВАТЬ ПО
        |        НаСкладе.Номенклатура,
        |        НаСкладе.ХарактеристикаНоменклатуры
        |    ) КАК НаСкладе
        |ПО
        |    СпрНоменклатура.Номенклатура = НаСкладе.Номенклатура
        |    И СпрНоменклатура.ХарактеристикаНоменклатуры = НаСкладе.ХарактеристикаНоменклатуры
        |ГДЕ
        |    ЕСТЬNULL(НаСкладе.Количество, 0) > 0
        |";
    КонецЕсли;

    ТекстЗапроса = ТекстЗапроса + "
    |УПОРЯДОЧИТЬ ПО
    |    СпрНоменклатура.Номенклатура.Наименование,
    |    СпрНоменклатура.ХарактеристикаНоменклатуры.Наименование
    |";

    // Соответствие имен полей в запросе и их представлений в отчете.
    СтруктураПредставлениеПолей = Новый Структура(
    "Номенклатура,   ХарактеристикаНоменклатуры,    Склад",
    "Номенклатура", "Характеристика номенклатуры", "Склад");

    ПостроительОтчета.Текст = ТекстЗапроса;

    ПостроительОтчета.ЗаполнитьНастройки();

    // Создадим список доступных отборов.
    СоответствиеДоступныхОтборов = Новый Соответствие;
    СоответствиеДоступныхОтборов.Вставить("Номенклатура", 0);
    СоответствиеДоступныхОтборов.Вставить("ХарактеристикаНоменклатуры", 0);
    СоответствиеДоступныхОтборов.Вставить("Склад", 0);

    Для Каждого ДоступноеПоле Из ПостроительОтчета.ДоступныеПоля Цикл
        Если СоответствиеДоступныхОтборов[ДоступноеПоле.Имя] =Неопределено Тогда
            ДоступноеПоле.Отбор = Ложь;
        Иначе
            ДоступноеПоле.Отбор = Истина;
        КонецЕсли;
    КонецЦикла;

    // Создадим массив отборов.
    МассивОтбора = Новый Массив;
    МассивОтбора.Добавить("Номенклатура");
    МассивОтбора.Добавить("ХарактеристикаНоменклатуры");

    Если ТолькоИмеющиесяВНаличии Тогда
        МассивОтбора.Добавить("Склад");
    КонецЕсли;

    Для Каждого ЭлементОтбора Из МассивОтбора Цикл
        Если ПостроительОтчета.Отбор.Найти(ЭлементОтбора) = Неопределено Тогда
            ПостроительОтчета.Отбор.Добавить(ЭлементОтбора);
        КонецЕсли;
    КонецЦикла;

    // Вызовем стандартную процедуру заполнения представлений.
    УправлениеОтчетами.ЗаполнитьПредставленияПолей(СтруктураПредставлениеПолей, ПостроительОтчета);

КонецПроцедуры // ЗаполнитьПостроительОтчета()

// Процедура перезаполняет цены в табличной части.
//
Процедура ПерезаполнитьЦены() Экспорт

    СтруктураЗначений = Новый Структура;
    СтруктураЗначений.Вставить("НовыйТипЦен", ТипЦен);

    ЗапросПоЦенам = Ценообразование.СформироватьЗапросПоЦенам(СтруктураЗначений,
       Перечисления.СпособыЗаполненияЦен.ПоЦенамНоменклатуры,
       Товары.ВыгрузитьКолонку("Номенклатура"),
       РабочаяДата,
       Неопределено).Выгрузить();

    ПустаяХарактеристика = Справочники.ХарактеристикиНоменклатуры.ПустаяСсылка();
    ТипЦенРассчитывается = ТипЦен.Рассчитывается;

    СтруктураКурса = МодульВалютногоУчета.ПолучитьКурсВалюты(Валюта, РабочаяДата);
    Курс = СтруктураКурса.Курс;
    Кратность = СтруктураКурса.Кратность;

    Для Каждого СтрокаТовара Из Товары Цикл
        ХарактеристикаНоменклатуры = СтрокаТовара.ХарактеристикаНоменклатуры;

        СтруктураПоиска = Новый Структура("Номенклатура", СтрокаТовара.Номенклатура);

        СтрокиЦен = ЗапросПоЦенам.НайтиСтроки(СтруктураПоиска);

        СтрокаБезХарактеристики = Неопределено;
        СтрокаСХарактеристикой = Неопределено;

        Для Каждого СтрокаЦен Из СтрокиЦен Цикл
            Если СтрокаЦен.ХарактеристикаНоменклатуры = ПустаяХарактеристика Тогда
                СтрокаБезХарактеристики = СтрокаЦен;
            ИначеЕсли СтрокаЦен.ХарактеристикаНоменклатуры = ХарактеристикаНоменклатуры Тогда
                СтрокаСХарактеристикой = СтрокаЦен;
            КонецЕсли;
        КонецЦикла;

        Если СтрокаСХарактеристикой <> Неопределено Тогда
            НайденнаяСтрока = СтрокаСХарактеристикой;
        ИначеЕсли СтрокаБезХарактеристики <> Неопределено Тогда
            НайденнаяСтрока = СтрокаБезХарактеристики;
        Иначе
            НайденнаяСтрока = Неопределено;
        КонецЕсли;

        Если (НайденнаяСтрока <> Неопределено) И (НайденнаяСтрока.Цена <> 0) Тогда
            Цена = НайденнаяСтрока.Цена * (1 + ?(ТипЦенРассчитывается, НайденнаяСтрока.ПроцентСкидкиНаценки / 100, 0));
            Цена = Ценообразование.ОкруглитьЦену(Цена, ТипЦен.ПорядокОкругления, ТипЦен.ОкруглятьВБольшуюСторону);
            Цена = Ценообразование.ПересчитатьЦенуПриИзмененииВалюты(Цена, НайденнаяСтрока.ВалютаЦены, Валюта, Курс, Кратность);

            СтрокаТовара.ЕдиницаИзмерения = НайденнаяСтрока.ЕдиницаИзмеренияЦены;
        Иначе
            Цена = 0;
        КонецЕсли;

        СтрокаТовара.Цена = Цена;
    КонецЦикла;

КонецПроцедуры // ПерезаполнитьЦены()

// Функция формирует табличный документ - печатная форма ценника.
//
// Возвращаемое значение:
//  ТабличныйДокумент - сформированный табличный документ или Неопределено, если есть ошибки.
//
Функция ПечатьЦенника() Экспорт

    Если НЕ ЗначениеЗаполнено(Организация) Тогда
        Предупреждение("Не выбрана организация!");
        Возврат Неопределено;
    КонецЕсли;

    ТабДокумент                     = Новый ТабличныйДокумент;
    ТабДокумент.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_Ценник";
    Макет                           = ПолучитьМакет("Ценник");
    КодЯзыкаПечать = ЛокализацияПовтИсп.ПолучитьЯзыкФормированияПечатныхФормДокументов();
    Макет.КодЯзыкаМакета = КодЯзыкаПечать;
    ОбластьЦенника                  = Макет.ПолучитьОбласть("Строка|Столбец");

    ДатаПечати = РабочаяДата;

    ТекСтолбец = 0;
    ТекСтрока  = 0;
    
    ДопКолонка = Константы.ДополнительнаяКолонкаПечатныхФормДокументов.Получить();
    Если ДопКолонка = Перечисления.ДополнительнаяКолонкаПечатныхФормДокументов.Артикул Тогда
        ТоварКод = "Артикул";
    ИначеЕсли ДопКолонка = Перечисления.ДополнительнаяКолонкаПечатныхФормДокументов.Код Тогда
        ТоварКод = "Код";
    Иначе
        ТоварКод = "";
    КонецЕсли;
    
    Для Каждого СтрокаТаблицы Из Товары Цикл
        Если СтрокаТаблицы.Печать Тогда
            Для Тмп = 1 По СтрокаТаблицы.Количество Цикл
                ОбластьЦенника.Параметры.Заполнить(СтрокаТаблицы);
                ОбластьЦенника.Параметры.НоменклатураНаименование        = СтрокаТаблицы.Номенклатура.НаименованиеПолное + ?(ТоварКод <> "", " " + СокрЛП(СтрокаТаблицы.Номенклатура[ТоварКод]), "");
                ОбластьЦенника.Параметры.ХарактеристикаНаименование      = СтрокаТаблицы.ХарактеристикаНоменклатуры;
                ОбластьЦенника.Параметры.ЕдиницаНаименование             = СтрокаТаблицы.ЕдиницаИзмерения;
                ОбластьЦенника.Параметры.Цена                            = ОбщегоНазначения.ФорматСумм(СтрокаТаблицы.Цена, Валюта, "00");
                ОбластьЦенника.Параметры.ДатаПечати                      = ДатаПечати;
                ОбластьЦенника.Параметры.Организация                     = Организация;
                ОбластьЦенника.Параметры.ОрганизацияНаименование         = Организация;

                Если ТекСтолбец = 0 Тогда
                    ТабДокумент.Вывести(ОбластьЦенника);
                Иначе
                    ТабДокумент.Присоединить(ОбластьЦенника);
                КонецЕсли;

                ТекСтолбец = ТекСтолбец + 1;

                Если ТекСтолбец = 5 Тогда
                    ТекСтрока  = ТекСтрока + 1;
                    ТекСтолбец = 0;
                КонецЕсли;

                Если ТекСтрока = 3 Тогда
                    ТекСтрока = 0;
                    ТабДокумент.ВывестиГоризонтальныйРазделительСтраниц();
                КонецЕсли;
            КонецЦикла;
        КонецЕсли;
    КонецЦикла;

    ТабДокумент.ТолькоПросмотр = Истина;

    Возврат ТабДокумент;

КонецФункции // ПечатьЦенника()

// Функция выполняет проверку параметров для заполнения цен.
//
// Возвращаемое значение:
//  Булево - Истина, если все параметры заданы.
//
Функция ПроверитьПараметрыЗаполненияЦен() Экспорт

    Если НЕ ЗначениеЗаполнено(ТипЦен) Тогда
        ОбщегоНазначения.СообщитьОбОшибке("Не выбран тип цен! Укажите тип цен и повторите перезаполнение цен.");
        Возврат Ложь;
    КонецЕсли;

    Если НЕ ЗначениеЗаполнено(Валюта) Тогда
        ОбщегоНазначения.СообщитьОбОшибке("Не выбрана валюта! Укажите валюту и повторите перезаполнение цен.");
        Возврат Ложь;
    КонецЕсли;

    Возврат Истина;

КонецФункции // ПроверитьПараметрыЗаполненияЦен()
#КонецЕсли