Версия для печати темы (https://pro1c.org.ua/index.php?s=7f6eeb2fb35874db62ba8650f219e107&showtopic=47250)

Нажмите сюда для просмотра этой темы в обычном формате

Украинский 1С форум: всё про 1С 8.3, 1С 8.2, 1С 8.1, 1С 8.0, 1С 7.7 _ Система компоновки данных _ Как на СКД выбрать первых не по документу а по полю

Автор: burza 15.08.18, 15:40

То есть есть отчет он выводит все приходы нал и безнал и проверочное поле от кого пришли деньги "Номер заявки".Как сделать так чтобы видно было не все приходи а только первые по заявке.

ВЫБРАТЬ
    ДенежныеСредстваНаличные.Сумма КАК СуммаПоСчету,
    ДенежныеСредстваНаличные.Заказ.Контрагент КАК Контрагент,
    ДенежныеСредстваНаличные.Заказ.Номер КАК НомерСчета,
    ДенежныеСредстваНаличные.Регистратор.Ссылка,
    ДенежныеСредстваНаличные.Регистратор.Дата КАК Дата
ИЗ
    РегистрНакопления.ДенежныеСредстваНаличные КАК ДенежныеСредстваНаличные
ГДЕ
    ДенежныеСредстваНаличные.СтатьяДвиженияДенежныхСредств = &СтатьяДвиженияДенежныхСредств
    И ДенежныеСредстваНаличные.Период >= &Период

ОБЪЕДИНИТЬ

ВЫБРАТЬ
    ДенежныеСредстваКПоступлениюБезналичные.Сумма,
    ДенежныеСредстваКПоступлениюБезналичные.Заказ.Контрагент,
    ДенежныеСредстваКПоступлениюБезналичные.Заказ.Номер,
    ДенежныеСредстваКПоступлениюБезналичные.Регистратор.Ссылка,
    ДенежныеСредстваКПоступлениюБезналичные.Регистратор.Дата
ИЗ
    РегистрНакопления.ДенежныеСредстваКПоступлениюБезналичные КАК ДенежныеСредстваКПоступлениюБезналичные
ГДЕ
    ДенежныеСредстваКПоступлениюБезналичные.Период >= &Период



Так я смогу посмотреть только первые приходы по заявке.

Автор: ed.kharkov 15.08.18, 16:28

burza @ Сегодня, 16:40 * ,
Добрый день.

Попробуйте сгрупировать записи по счету с суммируемым полем

МИНИМУМ(ДенежныеСредстваНаличные.Регистратор)


и

МИНИМУМ(ДенежныеСредстваКПоступлениюБезналичные.Регистратор)

Автор: burza 16.08.18, 8:33

ed.kharkov @ Вчера, 17:28 * ,
группировка тут не вариант, ибо сразу ее побывал



Автор: ed.kharkov 16.08.18, 10:26

burza @ Сегодня, 9:33 * ,
По одной заявке могут приходить только нал или безнал?
Или по одной заявке может быть и нал и безнал?

Автор: burza 16.08.18, 10:40

ed.kharkov @ Сегодня, 11:26 * ,
и нал и безнал.

как раз нужно выявить какой был имен о первый платеж. статистика.

Автор: ed.kharkov 16.08.18, 12:04

burza @ Сегодня, 11:40 * ,

ВЫБРАТЬ
    ДенежныеСредстваНаличные.Заказ КАК Заказ,
    ДенежныеСредстваНаличные.Регистратор.Ссылка КАК Платеж
ПОМЕСТИТЬ Платежи
ИЗ
    РегистрНакопления.ДенежныеСредстваНаличные КАК ДенежныеСредстваНаличные
ГДЕ
    ДенежныеСредстваНаличные.СтатьяДвиженияДенежныхСредств = &СтатьяДвиженияДенежныхСредств
    И ДенежныеСредстваНаличные.Период >= &Период

ОБЪЕДИНИТЬ

ВЫБРАТЬ
    ДенежныеСредстваКПоступлениюБезналичные.Заказ,
    ДенежныеСредстваКПоступлениюБезналичные.Регистратор.Ссылка
ИЗ
    РегистрНакопления.ДенежныеСредстваКПоступлениюБезналичные КАК ДенежныеСредстваКПоступлениюБезналичные
ГДЕ
    ДенежныеСредстваКПоступлениюБезналичные.Период >= &Период

;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ    
    Платежи.Заказ,
    МИНИМУМ(Платежи.Платеж) КАК Платеж
ПОМЕСТИТЬ ПервыеПлатежи
ИЗ
    Платежи КАК Платежи
СГРУПИРОВАТЬ ПО
    Платежи.Заказ
    
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ
    ПервыеПлатежи.Заказ.Контрагент КАК Контрагент,
    ПервыеПлатежи.Заказ.Номер КАК НомерСчета,
    ПервыеПлатежи.Платеж.Ссылка,
    ПервыеПлатежи.Платеж.Дата КАК Дата,
    ЕСТЬNULL(ДенежныеСредстваНаличные.Сумма, ДенежныеСредстваКПоступлениюБезналичные.Сумма) КАК СуммаПоСчету
ИЗ
    ПервыеПлатежи КАК ПервыеПлатежи
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ДенежныеСредстваНаличные КАК ДенежныеСредстваНаличные
        ПО ПервыеПлатежи.Заказ = ДенежныеСредстваНаличные.Заказ
            И ПервыеПлатежи.Платеж = ДенежныеСредстваНаличные.Регистратор
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ДенежныеСредстваКПоступлениюБезналичные КАК ДенежныеСредстваКПоступлениюБезналичные
        ПО ПервыеПлатежи.Заказ = ДенежныеСредстваКПоступлениюБезналичные.Заказ
            И ПервыеПлатежи.Платеж = ДенежныеСредстваКПоступлениюБезналичные.Регистратор

Автор: burza 16.08.18, 12:31

ed.kharkov @ Сегодня, 13:04 * ,
Спасибо

Украинский 1С форум: всё про 1С 8.3, 1С 8.2, 1С 8.1, 1С 8.0, 1С 7.7
https://pro1c.org.ua